# $Id: PKGBUILD 101477 2013-11-26 10:23:04Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Malte Rabenseifner <malte@zearan.de>
# Contributor: John Gerritse <reaphsharc@gmail.com>
# Maintainer (Parabola): Michał Masłowski <mtjm@mtjm.eu>
# Contributor (Parabola): André Silva emulatorman@parabola.nu>

pkgname=lsb-release
pkgver=1.4
pkgrel=14
pkgdesc="LSB version query program (Parabola rebranded)"
arch=('any')
url="http://www.linuxbase.org/"
license=('GPL2')
depends=('bash')
provides=('lsb-release-libre')
conflicts=('lsb-release-libre')
replaces=('lsb-release-libre')
install=lsb-release.install
source=(http://downloads.sourceforge.net/lsb/$pkgname-$pkgver.tar.gz
        lsb_release_description.patch)
md5sums=('30537ef5a01e0ca94b7b8eb6a36bb1e4'
         '72f562d8eaa8915ab85fba13e68c8d68')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  patch -Np0 < "$srcdir/lsb_release_description.patch"

  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  install -dm755 "$pkgdir/etc"
  echo "LSB_VERSION=$pkgver" >> "$pkgdir/etc/lsb-release"
  echo "DISTRIB_ID=Parabola" > "$pkgdir/etc/lsb-release"
  echo "DISTRIB_RELEASE=rolling" >> "$pkgdir/etc/lsb-release"
  echo "DISTRIB_DESCRIPTION=\"Parabola GNU/Linux-libre\"" >> "$pkgdir/etc/lsb-release"

  install -Dm 644 lsb_release.1.gz "$pkgdir/usr/share/man/man1/lsb_release.1.gz"
  install -Dm 755 lsb_release "$pkgdir/usr/bin/lsb_release"
}