# $Id: PKGBUILD 207916 2017-01-18 20:07:35Z stativ $
# Maintainer (Arch): Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor (Arch): flixie <69one@gmx.net>
# Contributor (Arch): Imanol Celaya <ornitorrincos@archlinux-es.org>
# Maintainer (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=luxrender
pkgver=1.6
_pkgver=b3f85cf7742f
pkgrel=8.parabola1
pkgdesc="Rendering system for physically correct, unbiased image synthesis, with opencl-mesa recommendation"
arch=('x86_64')
url="http://www.luxrender.net/"
license=('GPL')
depends=('boost-libs' 'embree' 'freeimage' 'openexr' 'openimageio' 'libpng' 'opencl-icd-loader' 'libgl' 'fftw')
optdepends=('blender-addon-luxrender: Blender exporter' 'qt4: Qt GUI' \
            'python: pylux Python interface'
            'opencl-mesa: OpenCL support for AMD GPUs')
makedepends=('cmake' 'boost' 'mesa' 'qt4' "luxrays=$pkgver" 'python' 'opencl-headers')
conflicts=("$pkgname-libre" "$pkgname-parabola")
replaces=("$pkgname-libre" "$pkgname-parabola")
source=($pkgname-$pkgver.tar.bz2::https://bitbucket.org/luxrender/lux/get/v${pkgver/./}.tar.bz2 \
        force_python3.diff luxrender-gcc7.patch)
sha256sums=('29144f657087644086928a66421df5d25fc4dccd05970200932f5693650ddecf'
            '916a45aec1326e6990c1ff9f141080c17a33ed793c44d1af9a2dacb9b21c19d2'
            'e51e33ac85c247696a0cab7751b5e91a23df5dac45af05b9ee68299e4a37dc6d')

prepare() {
  cd "$srcdir"/luxrender-lux-$_pkgver

  patch -Np1 < "$srcdir/force_python3.diff"
  # fix build with GCC 7 (Fedora)
  patch -p1 -i ../luxrender-gcc7.patch
}

build() {
  cd "$srcdir"/luxrender-lux-$_pkgver


  cmake . \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLUXRAYS_DISABLE_OPENCL=OFF \
    -DPYTHON_CUSTOM=ON \
    -DPYTHON_LIBRARIES=/usr/lib/libpython3.6m.so \
    -DPYTHON_INCLUDE_PATH=/usr/include/python3.6m/ \
    -DCMAKE_EXE_LINKER_FLAGS=-lpthread
  make
}

package() {
  cd "$srcdir"/luxrender-lux-$_pkgver
  make DESTDIR="$pkgdir" install

  # fix library path on x86_64
  [ "$CARCH" = "x86_64" ] && mv "$pkgdir"/usr/lib64 "$pkgdir"/usr/lib

  # install pylux
  install -D -m644 pylux.so "$pkgdir"/usr/lib/python3.6/pylux.so
}

# vim:set ts=2 sw=2 et: