# Contributor (Arch): Martin Wimpress <code@flexion.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=mate-icon-theme-faenza
pkgver=1.18.1
pkgrel=1.parabola1
pkgdesc="Faenza icon theme for MATE, without nonfree distros and application icons"
url="http://mate-desktop.org"
arch=('any')
license=('GPL')
makedepends=('mate-common')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
groups=('mate-extra')
source=("http://pub.mate-desktop.org/releases/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz")
sha1sums=('5058f2daeceb0728c96a5202dcdb0e04150c03d7')

prepare() {
    cd ${pkgname}-${pkgver}
    # remove nonfree distros and application logos
    for nonfree in debian fedora mandriva redhat suse ubuntu alien-arena flash rpmdrake teamviewer novell skype playonlinux picasa spotify; do
     find -name *$nonfree* -delete
    done
}

build() {
    cd ${pkgname}-${pkgver}
    ./autogen.sh
    ./configure \
        --prefix=/usr
    make
}

package() {
    cd ${pkgname}-${pkgver}
    make DESTDIR="${pkgdir}" install
}