# Maintainer (Arch): Brad Fanella <cesura@archlinux.org>
# Contributor (Arch): Martin Wimpress <code@flexion.org>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=mate-sensors-applet
pkgver=1.20.2
pkgrel=2
pkgrel+=.par1
pkgdesc="A MATE Panel applet to display readings from hardware sensors, including CPU temperature, fan speeds and voltage readings"
pkgdesc+=", without nonfree libxnvctrl support"
url="https://mate-desktop.org"
arch=('x86_64')
arch+=('i686' 'armv7h')
license=('GPL')
depends=('libatasmart' 'libnotify' 'lm_sensors' 'mate-panel')
makedepends=('docbook-xsl' 'intltool' 'itstool')
groups=('mate-extra')
conflicts=('mate-sensors-applet-gtk3')
replaces=('mate-sensors-applet-gtk3')
source=("https://pub.mate-desktop.org/releases/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz")
sha256sums=('cb0458deeac0d83ce94cce3d225186d0708af7b61e4469544df7092725ff1d4e')

build() {
	cd ${pkgname}-${pkgver}
    	./configure \
        	--prefix=/usr \
        	--libexecdir=/usr/lib/${pkgname}

    	#https://bugzilla.gnome.org/show_bug.cgi?id=656231
    	sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  	make
}

package() {
    	cd ${pkgname}-${pkgver}
    	make DESTDIR="${pkgdir}" install
}