# $Id: PKGBUILD 272944 2016-08-03 07:41:05Z eworm $
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=memtest86+
pkgver=5.01
pkgrel=2.parabola1
pkgdesc="An advanced memory diagnostic tool"
arch=('any')
url="http://www.memtest.org"
license=('GPL2')
makedepends_x86_64=('gcc-multilib' 'lib32-glibc')
source=("http://www.memtest.org/download/${pkgver}/${pkgname}-${pkgver}.tar.gz"
        '60_memtest86+'
        'doc-serialconsole.patch'
        'multiboot.patch'
        "${pkgname}-5.01-O0.patch"
        "${pkgname}-5.01-array-size.patch"
        'gcc-5.patch')
sha1sums=('eb4b6d70114db3c9ed320785da44c0ba8349c10c'
          '2aa2deeb7d7dc56f389aa1487b7a57b0d44ce559'
          '31dc513de83e207e8e160b9f43c67c7f6dda48f2'
          '53d3c0106644e6e085b8576e48e9981e5ccc3145'
          '83e20932625bb38137b01c0cbe1b8528629e0a76'
          '04654951868e73b53a67ce3288f2bd1843b40870'
          '225895ea59684a8d6a14c40d92db527dce8187c4')

prepare() {
  cd ${pkgname}-${pkgver}
  patch -p1 -i ${srcdir}/doc-serialconsole.patch
  patch -p1 -i ${srcdir}/multiboot.patch
  patch -p1 -i ${srcdir}/${pkgname}-5.01-O0.patch
  patch -p1 -i ${srcdir}/${pkgname}-5.01-array-size.patch
  patch -p1 -i ${srcdir}/gcc-5.patch
  sed -i 's|CC[=]gcc|CC=gcc -I/usr/include|
          s|[-]fno[-]stack[-]protector|-fno-stack-protector -fno-aggressive-loop-optimizations|
          \|scp memtest[.]bin|d
         ' Makefile
}

build() {
  cd ${pkgname}-${pkgver}
  make
}

package() {
  cd ${pkgname}-${pkgver}
  install -D -m644 ${pkgname%86+}.bin ${pkgdir}/boot/memtest86+/${pkgname%86+}.bin
  install -D -m755 ${srcdir}/60_memtest86+ ${pkgdir}/etc/grub.d/60_memtest86+
}