# $Id: PKGBUILD 151279 2012-02-25 12:34:03Z pierre $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor (Parabola): <andre.paulista@adinet.com.uy>

pkgname='mesa-demos-libre'
pkgver=8.0.1
pkgrel=2
arch=('i686' 'x86_64')
pkgdesc="Mesa demos and tools, libre"
url="http://mesa3d.sourceforge.net"
license=('custom')
depends=('glew')
provides=("mesa-demos=$pkgver")
replaces=('mesa-demos')
conflicts=('mesa-demos')
source=("ftp://ftp.freedesktop.org/pub/mesa/demos/${pkgver}/mesa-demos-${pkgver}.tar.bz2"
        mesa-demos-libre.patch
        LICENSE)
md5sums=('320c2a4b6edc6faba35d9cb1e2a30bf4'
         '1858e95d40ac9e5e0b59753ce9e673e3'
         '5c65a0fe315dd347e09b1f2826a1df5a')

build() {
  cd "${srcdir}/mesa-demos-${pkgver}"
  patch -Np1 -i "${srcdir}/mesa-demos-libre.patch"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/mesa-demos-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/mesa-demos"
  install -m755 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-demos/"
}