# Maintainer: Márcio Silva <coadde@parabola.nu>
# Contributor: André Silva <emulatorman@parabola.nu>

pkgbase=mesa
_pkgname=libcl
pkgname=$pkgbase-$_pkgname
pkgver=13.0.0
pkgrel=1
pkgdesc='Mesa 3-D OpenCL library and ICD loader'
arch=('i686' 'x86_64')
url="http://${pkgbase}3d.sourceforge.net"
license=('custom')
depends=("$pkgbase" 'libclc' 'libgcrypt' 'clang')


makedepends=('python2-mako' 'dri2proto' 'dri3proto' 'glproto' 'presentproto' 'python2' 'llvm')
provides=("$_pkgname" 'opencl-icd-loader')
conflicts=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx' 'ocl-icd')
replaces=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx')
source=(ftp://ftp.freedesktop.org/pub/$pkgbase/$pkgver/$pkgbase-$pkgver.tar.xz{,.sig}
        remove-libpthread-stubs.patch)
sha256sums=('94edb4ebff82066a68be79d9c2627f15995e1fe10f67ab3fc63deb842027d727'
            'SKIP'
            '75ab53ad44b95204c788a2988e97a5cb963bdbf6072a5466949a2afb79821c8f')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov@gmail.com>

prepare() {
  cd $srcdir/$pkgbase-$pkgver

  # Fix detection of libLLVM when builds with CMake
  sed -i 's/LLVM_SO_NAME=.*/LLVM_SO_NAME=LLVM/' configure

  # Now mesa checks for libpthread-stubs - so remove the check
  patch -Np1 -i ../remove-libpthread-stubs.patch

  autoreconf -fiv
}

build() {
  cd $srcdir/$pkgbase-$pkgver

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --with-gallium-drivers=nouveau,swrast \
    --with-egl-platforms=x11,drm,wayland \
    --enable-llvm-shared-libs \
    --enable-egl \
    --enable-gallium-llvm \
    --enable-opencl \
    --with-clang-libdir=/usr/lib
    # --with-dri-drivers=i965 \
  make

  # fake installation
  mkdir $srcdir/fakeinstall
  make DESTDIR=$srcdir/fakeinstall install
}

package() {
  cd $srcdir/$pkgbase-$pkgver

  install -vm755 -d $pkgdir/usr/lib/
  cp -rv $srcdir/fakeinstall/usr/lib/libOpenCL* $pkgdir/usr/lib/
  cp -rv $srcdir/fakeinstall/usr/lib/gallium-pipe $pkgdir/usr/lib/

  install -vm755 -d $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: