# $Id: PKGBUILD 173239 2016-05-01 10:50:33Z jlichtblau $
# Maintainer (Arch): Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor (Arch): Daenyth
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): Vrob (Markus Heuser) mheuser@mi.fu-berlin.de
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=ogmrip
pkgver=1.0.1
pkgrel=5.parabola1
pkgdesc="Libraries and GTK2 interface for DVD ripping using mencoder, without nonfree faac support"
arch=('i686' 'x86_64' 'armv7h')
url="http://ogmrip.sourceforge.net/"
license=('GPL')
depends=('libdvdread>=4.1.3' 'mplayer' 'mencoder' 'enca' 'pkg-config' 'gconf' 'libglade' 'libnotify' 'enchant')
makedepends=('patch' 'intltool' 'perl-xml-parser' 'lame' 'libtheora'
             'ogmtools' 'gpac' 'vorbis-tools' 'tesseract' 'python')
optdepends=('lame: support for the MP3 audio codec'
            'libtheora: decode and encode Ogg Theora files'
            'ogmtools: support for the Ogg Media container'
            'gpac: support for the MP4 container'
            'vorbis-tools: support for the Ogg Vorbis audio codec'
            'gocr: support for the SRT subtitle format'
            'ocrad: support for the SRT subtitle format'
            'tesseract: support for the SRT subtitle format')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
options=('!makeflags')
changelog=$pkgname.changelog
source=(https://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz
        enchant-2.patch)
sha256sums=('4e2e9778ac4da9fe1ab159e3dc6d4367b7a9dbd8f3501df99733ecedb25b02ff'
            '61fa359d44af8135ca80fbef2c98d6c30dcaf82e8817aeaf477d9203835f0ba8')

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 -i ../enchant-2.patch
}

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}

  ./configure --prefix=/usr --sysconfdir=/usr/share
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
}