# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (Arch): Sandy Carter <bwrsandman@gmail.com>
# Contributor: André Silva <emulatorman@hyperbola.info>
pkgname=openmw
pkgver=0.44.0
pkgrel=6
pkgrel+=.parabola1
pkgdesc="Open-source engine reimplementation for the role-playing game Morrowind"
pkgdesc+=", without without wizard installation support to install nonfree assets from Morrowind to run Morrowind"
arch=('x86_64')
arch+=('i686')
url="http://www.openmw.org"
license=('GPL3' 'MIT' 'custom')
depends=('openal' 'openscenegraph34' 'mygui' 'bullet' 'qt5-base' 'ffmpeg' 'sdl2' 'unshield' 'libxt')
makedepends=('cmake' 'boost' 'doxygen' 'ninja')
source=("https://github.com/OpenMW/openmw/archive/openmw-${pkgver}.tar.gz")
sha512sums=('1b178891274361b7821ac1d3d66976ed5d443545531499d98f7ed30823f3891172cc5dcb3f7382ba0f561774a92b9ad8805e0c9582b78d2f010e4ed661219017')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake "../$pkgname-$pkgname-$pkgver" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DDESIRED_QT_VERSION=5 \
    -DBUILD_ESSIMPORTER=OFF \
    -DBUILD_WIZARD=OFF \
    -GNinja
  ninja
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
}

# vim: ts=2 sw=2 et: