# Maintainer (Arch): David Runge <dvzrv@archlinux.org>
# Contributor (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Florian Pritz <bluewind@xinu.at>
# Contributor (Arch): Asa Marco <marcoasa90[at]gmail[.]com>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=openshot
pkgver=2.5.1
pkgrel=1
pkgrel+=.parabola1
pkgdesc="An award-winning free and open-source video editor"
pkgdesc+=", without nonfree faac recommendation"
arch=('any')
url="https://www.openshot.org/"
license=('GPL3')
depends=('ffmpeg' 'mlt' 'python-pyqt5' 'python-requests' 'libopenshot'
'libopenshot-audio' 'python-pyzmq' 'qt5-base' 'qt5-svg' 'qt5-webkit')
makedepends=('python-setuptools')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenShot/openshot-qt/archive/v$pkgver.tar.gz")
sha512sums=('8254a45254bbe523b6485b9598022de2c46ec30818e606ac4665790d29486693c4efe9f5bc55ee43d6342de6782cf0090e4bc880e831c08e3b1218bca555af14')

prepare() {
  mv -v "${pkgname}-qt-${pkgver}" "${pkgname}-${pkgver}"
}

build() {
  cd "${pkgname}-${pkgver}"
  python setup.py build
}

package() {
  cd "${pkgname}-${pkgver}"
  python setup.py install --skip-build \
                          --optimize=1 \
                          --prefix=/usr \
                          --root="${pkgdir}"
  install -vDm 644 {AUTHORS,{CONTRIBUTING,README}.md} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
}