# vim: set ts=2 sw=2 et:
# $Id: PKGBUILD 268273 2016-05-18 05:54:54Z allan $
# Maintainer (Arch): Dan McGee <dan@archlinux.org>
# Maintainer (Arch): Dave Reisner <dreisner@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
# Contributor: Nicolás Reynolds <fauno@kiwwwi.com.ar>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Daniel Milewski <niitotantei@riseup.net>

pkgname=pacman
pkgver=5.0.1
pkgrel=4.parabola2
pkgdesc="A library-based package manager with dependency support"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.archlinux.org/pacman/"
license=('GPL')
groups=('base' 'base-devel')
depends=('bash' 'glibc' 'libarchive' 'curl'
         'gpgme' 'pacman-mirrorlist' 'archlinux-keyring'
         'parabola-keyring')
depends_armv7h=('archlinuxarm-keyring')
makedepends=('asciidoc')
checkdepends=('python2' 'fakechroot')
optdepends=('cron: run specified programs at scheduled times and related tools')
provides=("$pkgname-contrib")
conflicts=("$pkgname-contrib" "$pkgname-parabola" 'cacert-dot-org')
replaces=("$pkgname-contrib" "$pkgname-parabola" 'cacert-dot-org')
backup=('etc/pacman.conf' 'etc/makepkg.conf')
options=('strip' 'debug')
source=(https://sources.archlinux.org/other/pacman/$pkgname-$pkgver.tar.gz{,.sig}
        "${arch[@]/#/$pkgname.conf.}"
        makepkg.conf.in
        $pkgname-keyring.service
        $pkgname-keyring.timer
        pacman-5.0.1-roundup.patch
        0001-Sychronize-filesystem.patch
        0002-Revert-close-stdin-before-running-install-scripts.patch
        0003-Revert-alpm_run_chroot-always-connect-parent2child-p.patch
        0001-makepkg-treat-pkgrel-more-similarly-to-pkgver.patch)
md5sums=('377a2664d6007d72d6d8a126add83bcf'
         'SKIP'
         '91acf59bee8951fc64c6d2a2734a60a9'
         '8e5794bb9e5ede9b34ef90fadd1d26dd'
         '22a5641e5b54d14de76f294c442a5baa'
         '19c91127e409cf24246de252be44eaa9'
         '11a5fac02651041e44d65d66c3538030'
         '7fb448e0d2b5b22da5ddc0040378efb0'
         '1a6573187531068d38cb4478cd20368c'
         '11869a104d0944cc86215098cf5a32bf'
         'd4692c3add0b0dab87036edad3f59626'
         'fd59d9fb04abadffb937082c288bb10c'
         '5c01220f49538d37bf1a424af46790d0')
validpgpkeys=('6645B0A8C7005E78DB1D7864F99FFE0FEAE999BD')  # Allan McRae <allan@archlinux.org>

prepare() {
  cd "$pkgname-$pkgver"

  # From Arch
  # v5.0.1..pacman-5.0.1..c2f97580
  patch -p1 -i $srcdir/pacman-5.0.1-roundup.patch

  # From Arch ARM
  if [ "${CARCH}" = "armv7h" ]; then
    patch -p1 -i $srcdir/0001-Sychronize-filesystem.patch
    patch -p1 -i $srcdir/0002-Revert-close-stdin-before-running-install-scripts.patch
    patch -p1 -i $srcdir/0003-Revert-alpm_run_chroot-always-connect-parent2child-p.patch
  fi

  # From Parabola
  patch -p1 -i $srcdir/0001-makepkg-treat-pkgrel-more-similarly-to-pkgver.patch
}

build() {
  cd "$pkgname-$pkgver"

  ./configure --prefix=/usr --sysconfdir=/etc \
    --localstatedir=/var --enable-doc \
    --with-scriptlet-shell=/usr/bin/bash \
    --with-ldconfig=/usr/bin/ldconfig
  make V=1
  make -C contrib

  # Generate the architecture-specific makepkg.conf files
  local carch mycarch mychost myflags myldflags
  for carch in "${arch[@]}"; do
    case $carch in
      i686)
        mycarch="i686"
        mychost="i686-pc-linux-gnu"
        myflags="-march=i686 -mtune=generic -O2 -pipe -fstack-protector-strong"
        ;;
      x86_64)
        mycarch="x86_64"
        mychost="x86_64-pc-linux-gnu"
        myflags="-march=x86-64 -mtune=generic -O2 -pipe -fstack-protector-strong"
        ;;
      armv7h)
        mycarch="armv7h"
        mychost="armv7l-unknown-linux-gnueabihf"
        myflags="-march=armv7-a -mfloat-abi=hard -mfpu=vfpv3-d16 -O2 -pipe -fstack-protector --param=ssp-buffer-size=4"
        ;;
    esac
    myldflags="-Wl,-O1,--sort-common,--as-needed,-z,relro"

    # set things correctly in the default conf file
    sed < "$srcdir/makepkg.conf.in" > "$srcdir/makepkg.conf.$carch" \
        -e "s|@CARCH[@]|$mycarch|g" \
        -e "s|@CHOST[@]|$mychost|g" \
        -e "s|@LDFLAGS[@]|$myldflags|g" \
        -e "s|@CARCHFLAGS[@]|$myflags|g"
  done
}

check() {
  make -C "$pkgname-$pkgver" check
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  make DESTDIR="$pkgdir" -C contrib install

  # install Parabola specific stuff
  install -dm755 "$pkgdir/etc"
  install -m644 "$srcdir/$pkgname.conf.$CARCH" "$pkgdir/etc/$pkgname.conf"
  install -m644 "$srcdir/makepkg.conf.$CARCH" "$pkgdir/etc/makepkg.conf"

  install -dm755 "$pkgdir/usr/share/pacman/defaults"
  local carch
  for carch in "${arch[@]}"; do
    install -m644 "$srcdir/$pkgname.conf.$carch" "$pkgdir/usr/share/pacman/defaults/"
    install -m644 "$srcdir/makepkg.conf.$carch" "$pkgdir/usr/share/pacman/defaults/"
  done

  # put bash_completion in the right location
  install -dm755 "$pkgdir/usr/share/bash-completion/completions"
  mv "$pkgdir/etc/bash_completion.d/pacman" "$pkgdir/usr/share/bash-completion/completions"
  rmdir "$pkgdir/etc/bash_completion.d"

  for f in makepkg pacman-key; do
    ln -s pacman "$pkgdir/usr/share/bash-completion/completions/$f"
  done

  install -Dm644 contrib/PKGBUILD.vim "$pkgdir/usr/share/vim/vimfiles/syntax/PKGBUILD.vim"

  install -Dm644 "$srcdir/pacman-keyring.service" "$pkgdir/usr/lib/systemd/system/pacman-keyring.service"
  install -Dm644 "$srcdir/pacman-keyring.timer" "$pkgdir/usr/lib/systemd/system/pacman-keyring.timer"
}