# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgbase=parabola-hackers
pkgname=(parabola-hackers parabola-hackers-nshd)
pkgver=20180426
pkgdesc='Programs for doing magic with hackers.git'
url='https://git.parabola.nu/packages/parabola-hackers.git/'
license=('GPL')

pkgrel=1
arch=('x86_64' 'i686')
makedepends=('go')
source=("https://repo.parabola.nu/other/$pkgbase/$pkgbase-$pkgver.tar.gz"{,.sig})
sha256sums=('ef1e1897e9801be2d2da2d47d9d4f60dc03594817bd6628df0a0e2526c673aa5'
            'SKIP')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9') # Luke Shumaker

build() {
	cd "$srcdir/$pkgbase-$pkgver"

	printf '%s\n' \
	    prefix='/usr' \
	    bindir='$(libexecdir)/$(PACKAGE)' \
	    libexecdir='$(libdir)' \
	    sysconfdir='/etc' \
	    >> config.mk

	make
}

check() {
	cd "$srcdir/$pkgbase-$pkgver"
	make check
}

package_parabola-hackers() {
	backup=(etc/$pkgbase.yml)
	depends=('ruby' 'colordiff')

	cd "$srcdir/$pkgbase-$pkgver"
	make DESTDIR="${pkgdir}" install
	find "$pkgdir" -type f \( -name 'nshd*' -o -name shadow \) -delete
	find "$pkgdir" -type d -empty -exec rmdir -p --ignore-fail-on-non-empty -- {} +
}

package_parabola-hackers-nshd() {
	pkgdesc='NSS and PAM integration for parabola-hackers'
	license=('GPL3')
	depends=("parabola-hackers=$pkgver" 'nss-pam-ldapd')
	backup=(etc/nshd/shadow)
	install=parabola-hackers-nshd.install
	replaces=(nshd)
	conflicts=(nshd)

	cd "$srcdir/$pkgbase-$pkgver"
	make DESTDIR="${pkgdir}" install
	find "$pkgdir" -type f -not \( -name 'nshd*' -o -name shadow \) -delete
	find "$pkgdir" -type d -empty -exec rmdir -p --ignore-fail-on-non-empty -- {} +

	install -d "${pkgdir}/usr/share/licenses/${pkgname}"
	cp -t "${pkgdir}/usr/share/licenses/${pkgname}" -- LICENSE.txt LICENSE.bsd*.txt
}