# Maintainer (Arch): David Runge <dvzrv@archlinux.org>
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Contributor (Arch): Gerardo Exequiel Pozzi <djgera@archlinux.org>
# Maintainer: David P. <megver83@parabola.nu>

pkgname=parabolaiso
pkgver=57
pkgrel=1
pkgdesc='Tools for creating Parabola GNU/Linux-libre live and install iso images'
arch=('any')
license=('GPL3')
url='https://git.parabola.nu/parabolaiso.git/'
depends=('arch-install-scripts' 'bash' 'dosfstools' 'e2fsprogs' 'libarchive'
'libisoburn' 'mtools' 'squashfs-tools')
makedepends=('git')
checkdepends=('shellcheck')
optdepends=(
  'edk2-ovmf: for emulating UEFI with run_parabolaiso'
  'erofs-utils: for experimental EROFS support in mkparabolaiso'
  'openssl: for codesigning support when building netboot artifacts'
  'qemu: for run_parabolaiso'
)
source=("git+https://git.parabola.nu/packages/parabolaiso.git#tag=v${pkgver}?signed")
sha256sums=('SKIP')
validpgpkeys=(6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78) # David P. <megver83@parabola.nu>

provides=("archiso=$pkgver")
conflicts=('archiso')
replaces=(${conflicts[@]})

check() {
  cd "${pkgbase}"
  make -k check
}

package() {
  cd "${pkgbase}"
  make DESTDIR="${pkgdir}" install
}