# Maintainer: Márcio Silva <coadde@hyperbola.info>
# based of pcre

_pkgname=pcre
pkgname=pcre-static
pkgver=8.39
pkgrel=2
pkgdesc='A library that implements Perl 5-style regular expressions (static libraries only)'
arch=('i686' 'x86_64' 'armv7h')
url='http://www.pcre.org/'
license=('BSD')
depends=('pcre')
options=('staticlibs')
validpgpkeys=('45F68D54BBE23FB3039B46E59766E084FB0F43D8') # Philip Hazel
source=("ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/$_pkgname-$pkgver.tar.bz2"{,.sig})
md5sums=('e3fca7650a0556a2647821679d81f585'
         'SKIP')

prepare() {
  cd $_pkgname-$pkgver
  # apply patch from the source array (should be a pacman feature)
  local filename
  for filename in "${source[@]}"; do
    if [[ "$filename" =~ \.patch$ ]]; then
      msg2 "Applying patch $filename"
      patch -p1 -N -i "$srcdir/$filename"
    fi
  done
  :
}

build() {
  cd $_pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --enable-unicode-properties \
    --enable-pcre16 \
    --enable-pcre32 \
    --enable-jit \
    --enable-pcregrep-libz \
    --enable-pcregrep-libbz2 \
    --enable-pcretest-libreadline
  make
}

check() {
  cd $_pkgname-$pkgver
  make -j1 check
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # remove conflicting files
  rm -vr ${pkgdir}/usr/{bin,include,lib/pkgconfig,share}
  rm -v ${pkgdir}/usr/lib/lib*.so*
}

# vim:set ts=2 sw=2 et: