# $Id: PKGBUILD 101605 2013-11-29 04:23:22Z eric $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: red_over_blue
# Contributor: neri

# Maintainer (Parabola): Márcio Silva <coadde@parabola.nu>
# Don't build povray before 3.7 version (it's nonfree software)

_pkgname=povray
pkgname=$_pkgname-libre
pkgver=3.7
pkgrel=4
epoch=1
pkgdesc='Script based raytracer for creating 3D graphics, without nonfree documentation'
arch=('x86_64' 'i686' 'mips64el')
license=('AGPL3')
url='http://povray.org/'
depends=('libtiff' 'libpng' 'boost-libs')
makedepends=('boost')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
replaces=("$_pkgname")
backup=("etc/povray/$pkgver/povray.conf"
        "etc/povray/$pkgver/povray.ini")
source=("https://github.com/POV-Ray/$_pkgname/archive/$pkgver-stable.zip"
        'povray3.7.0_rc3-user-conf.patch')
sha256sums=('1261d963327a4b04c09d56bbd7436d0062e6bf8363674e3fb4e240beefb5b5cb'
            '95b04ec4973e6e8a80fc83df2e3caff0b4d6699c4154144f3017d42cab7236e0')

prepare() {
  cd "$_pkgname-$pkgver-stable"

  cd unix
  sed 's/automake --w/automake --add-missing --w/g' -i prebuild.sh
  sed 's/dist-bzip2/dist-bzip2 subdir-objects/g' -i configure.ac
  ./prebuild.sh
  cd ..
  ./bootstrap
  patch -p1 < "$srcdir/povray3.7.0_rc3-user-conf.patch"
}

build() {
  cd "$_pkgname-$pkgver-stable"

  ./configure LIBS="-lboost_system -lboost_thread" COMPILED_BY='Parabola GNU/Linux-libre' \
    --prefix=/usr --sysconfdir=/etc
  make CXXFLAGS+="-w -lboost_system -lboost_thread"
  gzip -f povray.1
}

package() {
  cd "$_pkgname-$pkgver-stable"

  install -d "$pkgdir/usr/share/$_pkgname-$pkgver"
  cp -r icons include ini scenes scripts "$pkgdir/usr/share/$_pkgname-$pkgver"
  install -Dm755 unix/povray "$pkgdir/usr/bin/povray"
  install -Dm644 povray.conf "$pkgdir/etc/povray/$pkgver/povray.conf"
  install -Dm644 povray.ini "$pkgdir/etc/povray/$pkgver/povray.ini"
  install -Dm644 povray.1.gz "$pkgdir/usr/share/man/man1/povray.1.gz"
}

# vim:set ts=2 sw=2 et: