# $Id$
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=proguard
pkgver=5.3.3
pkgrel=1.parabola1
pkgdesc="free Java class file shrinker, optimizer, obfuscator, and preverifier"
arch=(any)
url="http://proguard.sourceforge.net/"
license=('GPL2')
depends=('java-runtime')
makedepends=('apache-ant' 'gradle' 'jh')
source=(http://downloads.sourceforge.net/proguard/proguard$pkgver.tar.gz)
sha256sums=('95bf9580107f00d0e26f01026dcfe9e7a772e5449488b03ba832836c3760b3af')

prepare() {
  cd "$srcdir/$pkgname$pkgver"
  rm -rv lib/*.jar
  rm -rv {docs,examples}
}

build() {
  cd "$srcdir/$pkgname$pkgver"
  ant basic anttask gradletask \
    -f buildscripts/build.xml \
    -Dgradle.home=/usr/share/java/gradle
}

package() {
  cd "$srcdir/$pkgname$pkgver/lib"

  mkdir -p $pkgdir/usr/bin
  mkdir -p $pkgdir/usr/share/proguard
  install -D -m0644 proguardgui.jar proguard.jar retrace.jar $pkgdir/usr/share/proguard/

  cat >$pkgdir/usr/bin/proguardgui <<EOF
#!/bin/sh
exec java -jar /usr/share/proguard/proguardgui.jar \$*
EOF
  chmod 0755 $pkgdir/usr/bin/proguardgui

  cat >$pkgdir/usr/bin/proguard <<EOF
#!/bin/sh
exec java -jar /usr/share/proguard/proguard.jar \$*
EOF
  chmod 0755 $pkgdir/usr/bin/proguard

  # FS#36268
  ln -s . $pkgdir/usr/share/proguard/lib

  # Install Maven artifacts
  export DESTDIR=$pkgdir
  for artifact in base gradle; do
    jh mvn-install net.sf.proguard $pkgname-$artifact $pkgver \
      "../buildscripts/maven/$artifact/pom.xml" \
      "$pkgname.jar"
  done
}