# $Id: PKGBUILD 176972 2013-02-03 07:11:03Z allan $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: eric <eric@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
# Contributor (Parabola): xihh <hahj87@gmail.com>

_pkgname=psutils
pkgname=psutils-libre
pkgver=1.17
pkgrel=4
arch=('i686' 'x86_64' 'mips64el')
pkgdesc="A set of postscript utilities, without nonfree files"
url="http://knackered.org/angus/psutils/"
license=('custom')
depends=('glibc' 'ghostscript')
provides=('psutils-lprng' 'psutils')
replaces=('psutils-lprng' 'psutils')
conflicts=('psutils-lprng' 'psutils')
options=('!makeflags')
source=("ftp://ftp.archlinux.org/other/psutils/${_pkgname}-${pkgver}.tar.gz"
        'psutils-1.17.diff'
        'libre.patch')
md5sums=('b161522f3bd1507655326afa7db4a0ad'
         '2b49e9e796000b42f42804d4b50a2be1'
         'a4beaf371607085e89ef190c1db7aee3')

build() {
  cd "${srcdir}/${_pkgname}"
  patch -Np1 -i "${srcdir}/psutils-1.17.diff"
  # apply patch to remove nonfree files support from Makefile
  patch -Np1 -i "${srcdir}/libre.patch"
  # remove nonfree files
  rm -v {fixmacps.{man,pl},md{68_0,71_0}.ps} 
  make -f Makefile.unix BINDIR=/usr/bin \
    INCLUDEDIR=/usr/include/psutils PERL=/usr/bin/perl \
    MANDIR=/usr/share/man/man1 \
    CFLAGS="$CFLAGS -DPAPER=\\\"letter\\\" -DUNIX -Wall" \
    CCFLAGS="$LDFLAGS"
}

package() {
  cd "${srcdir}/${_pkgname}"
  install -d -m755 "${pkgdir}/usr/include"
  install -d -m755 "${pkgdir}/usr/share/man"
  make -f Makefile.unix BINDIR="${pkgdir}/usr/bin" \
    INCLUDEDIR="${pkgdir}/usr/include/psutils" PERL=/usr/bin/perl \
    MANDIR="${pkgdir}/usr/share/man/man1" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${_pkgname}"
  install -m644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/"
}