# $Id: PKGBUILD 216383 2014-07-03 06:24:56Z fyan $
# Maintainer (Arch): Ronald van Haren <ronald.archlinux.org>
# Contributor (Arch): eric <eric@archlinux.org>
# Contributor (Arch): Tom Newsom <Jeepster@gmx.co.uk>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: xihh <hahj87@gmail.com>

_pkgname=psutils-libre
pkgname=psutils
pkgver=1.17
pkgrel=5.parabola1
arch=('i686' 'x86_64' 'mips64el' 'armv7h')
pkgdesc="A set of postscript utilities, without nonfree files"
url="http://knackered.org/angus/psutils/"
license=('custom')
depends=('glibc' 'ghostscript')
provides=('psutils-lprng')
replaces=('psutils-lprng' 'psutils-libre')
conflicts=('psutils-lprng' 'psutils-libre')
options=('!makeflags')
mksource=("ftp://ftp.archlinux.org/other/psutils/${pkgname}-${pkgver}.tar.gz"
          'libre.patch')
source=("https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
        'psutils-1.17.diff')
mkmd5sums=('b161522f3bd1507655326afa7db4a0ad'
           'a4beaf371607085e89ef190c1db7aee3')
md5sums=('75c88dc9e33877368d471dfa8652d96d'
         '2b49e9e796000b42f42804d4b50a2be1')

mksource() {
  cd "${srcdir}/${pkgname}"
  # apply patch to remove nonfree files support from Makefile
  patch -Np1 -i "${srcdir}/libre.patch"
  # remove nonfree files
  rm -v {fixmacps.{man,pl},md{68_0,71_0}.ps} 
}

build() {
  cd "${srcdir}/${pkgname}"
  patch -Np1 -i "${srcdir}/psutils-1.17.diff"
  make -f Makefile.unix BINDIR=/usr/bin \
    INCLUDEDIR=/usr/include/psutils PERL=/usr/bin/perl \
    MANDIR=/usr/share/man/man1 \
    CFLAGS="$CFLAGS -DPAPER=\\\"letter\\\" -DUNIX -Wall" \
    CCFLAGS="$LDFLAGS"
}

package() {
  cd "${srcdir}/${pkgname}"
  install -d -m755 "${pkgdir}/usr/include"
  install -d -m755 "${pkgdir}/usr/share/man"
  make -f Makefile.unix BINDIR="${pkgdir}/usr/bin" \
    INCLUDEDIR="${pkgdir}/usr/include/psutils" PERL=/usr/bin/perl \
    MANDIR="${pkgdir}/usr/share/man/man1" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/"
}