# $Id: PKGBUILD 155234 2016-01-03 19:23:59Z jelle $
# Maintainer (Arch):
# Contributor (Arch): Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
# Contributor (Arch): William Rea <sillywilly@gmail.com>
# Maintainer: fauno <fauno@kiwwwi.com.ar>
# Contributor: borgo <nomail>
# Contributor: André Silva <emulatorman@parabola.nu>

pkgbase=python-reportlab
pkgname=(python2-reportlab python-reportlab)
_origname=reportlab
pkgver=3.3.0
pkgrel=1.parabola1
pkgdesc="A proven industry-strength PDF generating solution, without nonfree Adobe T1 fonts support"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.reportlab.org/rl_toolkit.html"
depends=('freetype2')
conflicts=('python-reportlab<=2.5-2')
makedepends+=('python' 'python2' 'freetype2')
replaces=('python-reportlab<=2.5-2')
license=('custom')
source=("https://pypi.python.org/packages/source/r/reportlab/reportlab-$pkgver.tar.gz"
        'free-fonts.patch')
md5sums=('8ad6181b69ec515d4f6d8bb894682d5d'
         'eb3ac47734efb05b939fb88026aff8ed')

prepare() {
    cd $srcdir
    cp -rf ${_origname}-$pkgver "${_origname}2-$pkgver"

    _reportlab_source=("${_origname}-$pkgver" "${_origname}2-$pkgver")

    for x in ${_reportlab_source[@]}; do
      cd $srcdir/$x

      # remove nonfree Adobe T1 fonts support
      patch -p1 -i $srcdir/free-fonts.patch

      # Parabola contains those fonts from the ttf-bitstream-vera package
      rm -fv src/reportlab/fonts/{bitstream-vera-license.txt,Vera*}
    done
}

package_python2-reportlab() {
    conflicts+=('python2-reportlab-libre')
    replaces+=('python2-reportlab-libre')
    depends+=('python2' 'python2-pip' 'python2-pillow')

    cd "$srcdir/${_origname}2-$pkgver"
    python2 setup.py install --root=$pkgdir --optimize=1
    install -D -m644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/license.txt
}

package_python-reportlab() {
    conflicts+=('python-reportlab-libre')
    replaces+=('python-reportlab-libre')
    depends+=('python3' 'python-pip' 'python-pillow')

    cd "$srcdir/${_origname}-$pkgver"
    python3 setup.py install --root=$pkgdir --optimize=1
    install -D -m644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/license.txt
}


check() {
    cd ${srcdir}/${_origname}-${pkgver}
    python2 setup.py tests
    python setup.py tests
}