#Maintainer (Arch): Xyne <ac xunilhcra enyx, backwards>
#Maintainer (Hyperbola): André Silva <emulatorman@parabola.nu>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=reflector
pkgver=2018
pkgrel=2.parabola1
pkgdesc='A Python 3 module and script to retrieve and filter the latest Pacman mirror list (Parabola rebranded)'
arch=(any)
license=(GPL)
url="https://xyne.archlinux.ca/projects/reflector"
replaces=(${pkgname}-parabola)
conflicts=(${pkgname}-parabola)
depends=(python3)
optdepends=('rsync: rate rsync mirrors')
source=(
  https://xyne.archlinux.ca/projects/reflector/src/reflector-2018.tar.xz
  https://xyne.archlinux.ca/projects/reflector/src/reflector-2018.tar.xz.sig
  rebranding.patch
)
sha512sums=(
  35d6d300af0a5fcde0a221b969693597618a41c12deb02f35e1123340b4168fe34d1f4d7c02fa46a3a6ff6327aaed6ccb952c8e320aeff6578839c8a2f90cdd4
  a4afc02df892382c17b7fb5000c4dd9bdc7e7c5ee2380fa85fbf08ac01cd8280f026c3a53cad4681766d9f54a1e2ba108e86524f82bffef74bcfe8b128c45d62
  242fe3ae1850d2beab775fff96b173dfd5ed71178d6b3324592a179e4658209b0f0cf0bc25faba6ff31a3b379877723c2117feb9570bad6adb5339f621932ec5
)
validpgpkeys=('EC3CBE7F607D11E663149E811D1F0DC78F173680')

prepare ()
{
  cd "$srcdir/$pkgname-$pkgver"
  # Rebranding for Parabola
  patch -Np1 -i "$srcdir/rebranding.patch"
}

package ()
{
  cd "$srcdir/$pkgname-$pkgver"
  python3 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  install -Dm755 "$srcdir/$pkgname-$pkgver/$pkgname" "$pkgdir/usr/bin/$pkgname"
}


# vim: set ts=2 sw=2 et: