#Maintainer (Arch): Xyne <ac xunilhcra enyx, backwards>
#Maintainer: André Silva <emulatorman@hyperbola.info>
pkgname=reflector
pkgver=2017.6
pkgrel=1.parabola1
pkgdesc='A Python 3 module and script to retrieve and filter the latest Pacman mirror list (Parabola rebranded)'
arch=(any)
license=(GPL)
url="http://xyne.archlinux.ca/projects/reflector"
replaces=(${pkgname}-parabola)
conflicts=(${pkgname}-parabola)
depends=(python3)
optdepends=('rsync: rate rsync mirrors')
source=(
  http://xyne.archlinux.ca/projects/reflector/src/reflector-2017.6.tar.xz
  http://xyne.archlinux.ca/projects/reflector/src/reflector-2017.6.tar.xz.sig
  rebranding.patch
)
sha512sums=(
  aaccb8444dcbcdc145df0165dcfe6ddcb39aac606d70f6734a55dc3303c34273d2eb91695d2ea1a54bc72ea74938308fd6ecbb00c91d8d09692e8e8452819797
  af58a54a52e8a7d08b11aa358fe24ffe4ece23002ffaf6f8d1ec22e9d6a116bf1057cbab64b38ee2be341bc7601897ce0a3801086f165f31c5ecd6e708a78f32
  242fe3ae1850d2beab775fff96b173dfd5ed71178d6b3324592a179e4658209b0f0cf0bc25faba6ff31a3b379877723c2117feb9570bad6adb5339f621932ec5
)
md5sums=(
  4d1e1ab5c6595eda7accaba84562e8a3
  0f5cfc56fcf5b40b0d37f4ed032afea0
  9ee7955d3238c2ea4fc816139bbbc847
)
validpgpkeys=('EC3CBE7F607D11E663149E811D1F0DC78F173680')

prepare ()
{
  cd "$srcdir/$pkgname-$pkgver"
  # Rebranding for Parabola
  patch -Np1 -i "$srcdir/rebranding.patch"
}

package ()
{
  cd "$srcdir/$pkgname-$pkgver"
  python3 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  install -Dm755 "$srcdir/$pkgname-$pkgver/$pkgname" "$pkgdir/usr/bin/$pkgname"
}


# vim: set ts=2 sw=2 et: