#Maintainer (Arch): Xyne <ac xunilhcra enyx, backwards>
#Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=reflector
pkgver=2015.12
pkgrel=2.parabola1
pkgdesc='A Python 3 module and script to retrieve and filter the latest Pacman mirror list (Parabola rebranded)'
arch=(any)
license=(GPL)
url="http://xyne.archlinux.ca/projects/reflector"
replaces=(${pkgname}-parabola)
conflicts=(${pkgname}-parabola)
depends=(python3)
optdepends=('rsync: rate rsync mirrors')
source=(
  http://xyne.archlinux.ca/projects/reflector/src/reflector-2015.12.tar.xz
  http://xyne.archlinux.ca/projects/reflector/src/reflector-2015.12.tar.xz.sig
  rebranding.patch
)
sha512sums=(
  9c1da4688fd2e2b5bd9f1498b9b9252043de3742eb86f6e8aecae3d9c2779fca2baadf64a5103abb08db01b4ecd5ccb61127bcdbcef64f972405371b631e013d
  5a689419ac03f6a1d2a6231c195b9653d4654a3062b21bb6791211455870154a305c39856f377102c6c982541cca945f9b381b7922d4d2a2e9b84e238a25acea
  242fe3ae1850d2beab775fff96b173dfd5ed71178d6b3324592a179e4658209b0f0cf0bc25faba6ff31a3b379877723c2117feb9570bad6adb5339f621932ec5
)
md5sums=(
  b2997306594aa064bfeff3533132b174
  43a73486fed553664e3a484ebdff501e
  9ee7955d3238c2ea4fc816139bbbc847
)
validpgpkeys=('EC3CBE7F607D11E663149E811D1F0DC78F173680')

prepare ()
{
  cd "$srcdir/$pkgname-$pkgver"
  # Rebranding for Parabola
  patch -Np1 -i "$srcdir/rebranding.patch"
}

package ()
{
  cd "$srcdir/$pkgname-$pkgver"
  python3 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  install -Dm755 "$srcdir/$pkgname-$pkgver/$pkgname" "$pkgdir/usr/bin/$pkgname"
}


# vim: set ts=2 sw=2 et: