# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): Themaister <maister@archlinux.us>
# Contributor (Arch): lifning <definelightning@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>

# rationale for inclusion in [libre]:
#  - removed updated urls (libre.patch)

pkgname=retroarch
pkgver=1.7.6
pkgrel=2
pkgrel+=.parabola1
pkgdesc='Reference frontend for the libretro API'
arch=(x86_64)
arch+=(i686 armv7h)
url=http://www.libretro.com/
license=(GPL)
groups=(libretro)
depends=(
  alsa-lib
  libass.so
  libavcodec.so
  libavformat.so
  libavutil.so
  libdrm
  libfreetype.so
  libgl
  libpulse
  libswresample.so
  libswscale.so
  libudev.so
  libusb-1.0.so
  mesa
  openal
  qt5-base
  sdl2
  v4l-utils
  zlib
)
makedepends=(
  git
  libx11
  libxcb
  libxext
  libxinerama
  libxkbcommon
  libxrandr
  libxv
  libxxf86vm
  vulkan-icd-loader
  wayland
  wayland-protocols
)
optdepends=(
  'libretro-overlays: Collection of overlays'
  'libretro-shaders: Collection of shaders'
  'libxinerama: X11 support'
  'libxrandr: X11 support'
  'python: retroarch-cg2glsl'
  'retroarch-assets-xmb: XMB menu assets'
  'wayland: Wayland support'
)
backup=(etc/retroarch.cfg)
source=(
  git+https://github.com/libretro/RetroArch.git#tag=v${pkgver}
  retroarch-config.patch
  libre.patch
)
sha256sums=('SKIP'
            '7857cff30c45721b66666828ca9edbb2923817c6c64591be3f58fe019277103e'
            '0a2afb0e4f8e45b3366034e23ebbf980fa9cf9108d98fd167fda9e15a47c8452')

prepare() {
  cd RetroArch

  patch -Np1 -i ../retroarch-config.patch
  patch -Np1 -i ${srcdir}/libre.patch
}

build() {
  cd RetroArch

  ./configure \
    --prefix='/usr' \
    --disable-cg \
    --disable-jack \
    --disable-oss \
    --disable-sdl
  make
  make -C libretro-common/audio/dsp_filters
  make -C gfx/video_filters
}

package() {
  cd RetroArch

  make DESTDIR="${pkgdir}" install

  install -Dm 644 libretro-common/audio/dsp_filters/*.{dsp,so} -t "${pkgdir}"/usr/lib/retroarch/filters/audio/
  install -Dm 644 gfx/video_filters/*.{filt,so} -t "${pkgdir}"/usr/lib/retroarch/filters/video/
}

# vim: ts=2 sw=2 et: