# $Id: PKGBUILD 223594 2014-09-27 21:07:22Z heftig $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): dorphell <dorphell@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Maintainer: Márcio Silva <coadde@parabola.nu>
# Maintainer (Connochaetos): Henry Jensen <hjensen@connochaetos.org>

pkgname=sdl
pkgver=1.2.15
pkgrel=7.parabola2
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard, without nonfree riva_mmio.h file"
arch=('i686' 'x86_64' 'mips64el' 'armv7h')
url="http://www.libsdl.org"
license=('LGPL')
conflicts=('sdl-libre')
replaces=('sdl-libre')
depends=('glibc' 'libxext' 'libxrender' 'libx11')
makedepends=('alsa-lib' 'mesa' 'libpulse' 'glu')
optdepends=('alsa-lib: ALSA audio driver'
            'libpulse: PulseAudio audio driver')
options=('staticlibs')
mksource=(http://www.libsdl.org/release/SDL-${pkgver}.tar.gz
          libre.patch)
source=(https://repo.parabola.nu/other/${pkgname}-libre/SDL-libre-${pkgver}.tar.gz
        SDL-1.2.10-GrabNotViewable.patch
        SDL-1.2.15-SDL_EnableUNICODE_drops_keyboard_events.patch
        SDL-1.2.15-const_XData32.patch
        SDL-1.2.15-ignore_insane_joystick_axis.patch
        SDL-1.2.15-no-default-backing-store.patch
        SDL-1.2.15-x11-Bypass-SetGammaRamp-when-changing-gamma.patch
        sdl-1.2.14-fix-mouse-clicking.patch
        sdl-1.2.14-disable-mmx.patch
        libsdl-1.2.15-resizing.patch
        X11_KeyToUnicode.patch)
mkmd5sums=('9d96df8417572a2afb781a7c4c811a85'
           '5c665f72b8a2adc97a91f6db6f2da79a')
md5sums=('c6e53ef16fa347ed066c3d68fe93c378'
         '37ad001a4d2ff924a5fab356b49f8a78'
         '8d5a61a0adf1a302695a30141f402712'
         'd6a1bfa054507f281338626e5f12d74b'
         'e382e5b7449e95969c5ba4084b0aab39'
         '1b0578c76453813eb4eaf0125ce242db'
         '321377e38e2db7f1baf43c392e165dd5'
         '04d8c179f125e04bcd4c9d60e013c2d7'
         'e5c16b7611f62c7cb25f0534eff68852'
         '3dd50347d8856160a9cbd7f80383a1f8'
         'edea272dff4698470877c016d818918d')

mksource() {
  cd SDL-$pkgver
  patch -Np0 -i ../libre.patch
}

prepare() {
  cd SDL-$pkgver
  patch -Np1 -i ../SDL-1.2.10-GrabNotViewable.patch
  patch -Np1 -i ../SDL-1.2.15-SDL_EnableUNICODE_drops_keyboard_events.patch
  patch -Np1 -i ../SDL-1.2.15-const_XData32.patch
  patch -Np1 -i ../SDL-1.2.15-ignore_insane_joystick_axis.patch
  patch -Np1 -i ../SDL-1.2.15-no-default-backing-store.patch

  # https://bugs.freedesktop.org/show_bug.cgi?id=27222
  patch -Np1 -i ../SDL-1.2.15-x11-Bypass-SetGammaRamp-when-changing-gamma.patch

  patch -Np1 -i ../sdl-1.2.14-fix-mouse-clicking.patch
  patch -Np1 -i ../sdl-1.2.14-disable-mmx.patch
  patch -Np1 -i ../libsdl-1.2.15-resizing.patch
  patch -Np1 -i ../X11_KeyToUnicode.patch
}

build() {
  cd SDL-$pkgver
  ./configure --prefix=/usr --disable-nasm --enable-alsa \
              --with-x --disable-rpath --disable-static
  make
}

package() {
  cd SDL-$pkgver
  make DESTDIR="$pkgdir" install
}