# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): Alessio 'mOLOk' Bolognino <themolok@gmail.com>
# Contributor (Arch): shamrok <szamrok@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>

# parabola changes and rationale:
#  - removed smtube support

pkgname=smplayer
pkgver=18.2.0
pkgrel=1.parabola1
pkgdesc='Media player with built-in codecs that can play virtually all video and audio formats, without nonfree smtube support'
url='https://www.smplayer.info/'
arch=('x86_64' 'i686' 'armv7h')
license=('GPL')
depends=('qt5-script' 'mpv' 'hicolor-icon-theme' 'libx11' 'zlib' 'gcc-libs')
makedepends=('qt5-tools')
optdepends=('smplayer-themes: icon themes collection'
            'smplayer-skins: skin themes collection'
            'youtube-dl: youtube videos and streaming'
            'mplayer: alternative multimedia engine')
source=(https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2
        libre.patch)
sha256sums=('0e6e19dc90dd7a2bd0f920bff8c53f8a5450abd5907847726d47d172a51e76d0'
            'e86a0881d6696dfe2b5a2742947f317090194beab4986df7e9ac8845727e78de')
sha512sums=('43be64b82f77b223ef885b63b1bb3302b96cb93897cbf66df6272075bcfb76dbf11091526ae2b1bcde6845e25053a31456361fbd841a4dad8d229bacfab8bdb5'
            '813efc30a754015d8bca9391ed3b586481c2cd931a0b234a8cb94cdad7ae92b8976aabd05569099900ce65b8f2fd39d39da0dddff46bfe10891dd5edc4f12283')

prepare() {
  cd ${pkgname}-${pkgver}
  # disable SMTube support
  patch -p1 -i $srcdir/libre.patch
  # fix GNU/Linux name
  sed -i 's|Linux|GNU/Linux|' src/smplayer.cpp
  # make build reproducible, we compress ourselves
  sed '/gzip -9/d' -i Makefile
}

build() {
  cd ${pkgname}-${pkgver}
  make PREFIX=/usr \
    DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
    QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE \
    CFLAGS_EXTRA="${CFLAGS} ${LDFLAGS}"
}

package() {
  cd ${pkgname}-${pkgver}
  make DOC_PATH=/usr/share/doc/smplayer \
    DESTDIR="${pkgdir}" PREFIX=/usr install
}

# vim: ts=2 sw=2 et: