# $Id: PKGBUILD 279047 2016-10-20 14:44:55Z remy $
# Maintainer (Arch): Rémy Oudompheng <remy.archlinux.org>
# Maintainer: Michał Masłowski <mtjm@mtjm.eu>
# Contributor: André Silva <emulatorman@parabola.nu>

_pkgname=texlive-fontsextra-libre
pkgname=texlive-fontsextra
pkgver=2016.42286
_revnr=${pkgver#2016.}
pkgrel=1.parabola1
pkgdesc="TeX Live - all sorts of extra fonts, without nonfree add-on packages"
license=('GPL')
arch=(any)
depends=('texlive-core')
groups=('texlive-most')
replaces=('texlive-fontsextra-libre')
conflicts=('texlive-fontsextra-libre')
url='http://tug.org/texlive/'
mksource=("https://sources.archlinux.org/other/texlive/$pkgname-$pkgver-src.zip")
noextract=("$pkgname-$pkgver-src.zip")
source=("https://repo.parabola.nu/other/$_pkgname/$_pkgname-$pkgver-src.tar.xz" "$pkgname.maps")
options=('!emptydirs')
mkmd5sums=('ab88c3ad092484ccaed441e524369b61')
md5sums=('fdaeb8b58d68c02aaec9bca5f71017f7'
         'd55d63922852aaec6988d4c4af1b1cd2')

mksource() {
   mkdir $pkgname-$pkgver
   pushd $pkgname-$pkgver
   bsdtar xfv ../$pkgname-$pkgver-src.zip

   # remove nonfree packages
   # no specific free license
   rm -v ogham.tar.xz

   popd
}

prepare() {
   cd $srcdir/$pkgname-$pkgver
   echo -n "   --> extracting all packages... "
   for p in *.tar.xz; do
     bsdtar -xf $p
   done
   echo "done"
   rm -rf {tlpkg,doc,source} || true

   # remove nonfree packages references from package list
   sed -ri '/^ogham /d' CONTENTS
}

package() {
   cd $srcdir/$pkgname-$pkgver
   install -m755 -d $pkgdir/var/lib/texmf/arch/installedpkgs
   sed -i '/^#/d' CONTENTS
   install -m644 CONTENTS $pkgdir/var/lib/texmf/arch/installedpkgs/${pkgname}_${_revnr}.pkgs
   install -m644 $srcdir/$pkgname.maps $pkgdir/var/lib/texmf/arch/installedpkgs/
   install -m755 -d $pkgdir/usr/share
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \;
     find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \;
   done
   if [[ -d texmf-dist ]]; then
     find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \;
     find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \;
   fi
   if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
     find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
}