# $Id: PKGBUILD 157994 2012-04-30 20:56:00Z ibiru $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Alexander Baldeck <alexander@archlinux.org>
# Contributor: Dale Blount <dale@archlinux.org>
# Contributor: Anders Bostrom <anders.bostrom@home.se>
# Maintainer (Parabola): André Silva <andre.paulista@adinet.com.uy>

pkgname=thunderbird-libre
pkgver=12.0.1
pkgrel=1
pkgdesc="Standalone Mail/News reader"
arch=('i686' 'x86_64')
license=('MPL' 'GPL')
url="http://www.mozilla.org/thunderbird/"
depends=('alsa-lib' 'dbus-glib' 'desktop-file-utils' 'gtk2' 'hicolor-icon-theme' 'hunspell' 'libevent' 'libnotify' 'libvpx' 'libxt' 'mime-types' 'mozilla-common' 'nss' 'sqlite' 'startup-notification')
makedepends=('unzip' 'zip' 'pkg-config' 'python2' 'wireless_tools' 'yasm' 'mesa' 'autoconf2.13')
optdepends=('libcanberra: for sound support')
replaces=('thunderbird')
conflicts=('thunderbird')
provides=("thunderbird=$pkgver")
install=thunderbird.install
source=(ftp://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/source/thunderbird-$pkgver.source.tar.bz2
        mozconfig
        thunderbird.desktop
        thunderbird-install-dir.patch
        channel-prefs.js
        vendor.js
        gcc47.patch
        clrf.patch
        searchplugins-libre.patch)
md5sums=('64cacde4cb2b1e8736f1c3a0ea6a02db'
         '41511a6bcdd04cf56706218e4670e631'
         'af3e5b344d2edf1c7d61bb0a5a96de9a'
         'aea906acf72c43dd82ead2fabcc1c6db'
         '476ec205162340fb0679f522c9d31c3b'
         '5a53179d14ae9631b7afe5e4d0fc0b25'
         '1e3ad86899c61f0993c429d10913edb4'
         'abe8f73faa71ea2a1e4c6f5a33f56c27'
         '6a1d132b0275876678cb0b08c527805a')

build() {
  cd comm-release
  patch -Np1 -i "$srcdir/thunderbird-install-dir.patch"
  patch -Np1 -i "$srcdir/gcc47.patch"
  patch -Np1 -i "$srcdir/clrf.patch"

  # Removing non-free search plugins replacing them with duckduckgo and identi.ca
  patch -Np1 -i "$srcdir/searchplugins-libre.patch"

  cp "$srcdir/mozconfig" .mozconfig

  export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/thunderbird"
  export PYTHON="/usr/bin/python2"

  make -j1 -f client.mk build MOZ_MAKE_FLAGS="$MAKEFLAGS"
}

package() {
  cd comm-release
  make -j1 -f client.mk DESTDIR="$pkgdir" install

  install -m644 "$srcdir"/vendor.js "$pkgdir/usr/lib/thunderbird/defaults/pref/"

  for i in 16x16 22x22 24x24 32x32 48x48 256x256; do
      install -Dm644 other-licenses/branding/thunderbird/mailicon${i/x*/}.png \
          "$pkgdir/usr/share/icons/hicolor/$i/apps/thunderbird.png"
  done

  install -Dm644 "$srcdir/thunderbird.desktop" \
      "$pkgdir/usr/share/applications/thunderbird.desktop"

  rm -rf "$pkgdir"/usr/lib/thunderbird/{dictionaries,hyphenation}
  ln -sf /usr/share/hunspell "$pkgdir/usr/lib/thunderbird/dictionaries"
  ln -sf /usr/share/hyphen "$pkgdir/usr/lib/thunderbird/hyphenation"

  # We don't want the development stuff
  rm -r "$pkgdir"/usr/{include,lib/thunderbird-devel,share/idl}

# Recommend free addons
  cp --remove-destination "${srcdir}/channel-prefs.js" \
     "${pkgdir}/usr/lib/thunderbird/defaults/pref/channel-prefs.js"
}