# Maintainer (Arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor (Arch): xduugu
# Contributor (Arch): nh2
# Contributor (Arch): Steven Davidovitz <steviedizzle ð gmail đ com>
# Contributor (Arch): Nick B <Shirakawasuna ð gmail đ com>
# Contributor (Arch): Christof Musik <christof ð senfdax đ de>
# Contributor (Arch): Stefan Rupp <archlinux ð stefanrupp đ de>
# Contributor (Arch): Ignas Anikevicius <anikevicius ð gmail đ com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Márcio Silva <coadde@parabola.nu>

_kernelname=-lts

if [[ ${_kernelname} == "" ]]; then
  _basekernel=4.8
  _archrel=4
  _parabolarel=1
elif [[ ${_kernelname} == -lts ]]; then
  _basekernel=4.4
  _archrel=5
  _parabolarel=1
elif [[ ${_kernelname} == -grsec ]]; then
  _basekernel=4.8
  _archrel=1
  _parabolarel=1
elif [[ ${_kernelname} == -pck ]]; then
  _basekernel=4.8
  _archrel=1
  _parabolarel=1
elif [[ ${_kernelname} == -knock ]]; then
  _basekernel=4.8
  _archrel=1
  _parabolarel=1
elif [[ ${_kernelname} == -lts-knock ]]; then
  _basekernel=4.4
  _archrel=1
  _parabolarel=1
elif [[ ${_kernelname} == -grsec-knock ]]; then
  _basekernel=4.8
  _archrel=1
  _parabolarel=1
elif [[ ${_kernelname} == -grsec-xen ]]; then
  _basekernel=4.8
  _archrel=1
  _parabolarel=1
elif [[ ${_kernelname} == -rt ]]; then
  _basekernel=4.6
  _archrel=1
  _parabolarel=1
elif [[ ${_kernelname} == -pae ]]; then
  _basekernel=4.8
  _archrel=1
  _parabolarel=1
elif [[ ${_kernelname} == -xen ]]; then
  _basekernel=4.8
  _archrel=1
  _parabolarel=1
fi

__pkgname=tp-smapi
_pkgname=tp_smapi
pkgname=${_pkgname}${_kernelname}
pkgver=0.42
pkgrel=${_archrel}.parabola${_parabolarel}.basekernel${_basekernel}
_extramodules=extramodules-${_basekernel}${_kernelname}
pkgdesc="Modules for ThinkPad's SMAPI functionality (built for the linux-libre${_kernelname} kernel package)"
arch=('i686' 'x86_64')
url='https://github.com/evgeni/tp_smapi'
license=('GPL')

# Generic (you shouldn't have to modify any of these variables)
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
depends=("linux-libre${_kernelname}>=${_basekernel}" "linux-libre${_kernelname}<${_toohigh}")
makedepends=("linux-libre${_kernelname}-headers>=${_basekernel}" "linux-libre${_kernelname}-headers<${_toohigh}")
makedepends+=('libelf')

replaces=("${_pkgname}-libre${_kernelname}" "${_pkgname}-parabola${_kernelname}")
conflicts=("${_pkgname}-libre${_kernelname}" "${_pkgname}-parabola${_kernelname}")
if [[ ${_kernelname} != "" ]]; then
  provides=("${_pkgname}")
fi

install='kmod.install'
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/evgeni/${_pkgname}/archive/${__pkgname}/${pkgver}.tar.gz")
md5sums=('6a51d3aa459ad7a6ebfbb8c29527b3ee')

build() {
  cd "${srcdir}/${_pkgname}-${__pkgname}-${pkgver}"

  _kernver="$(cat /usr/lib/modules/${_extramodules}/version)"

  make HDAPS=1 KVER="${_kernver}" KBASE="/usr/lib/modules/${_kernver}"
}

package() {
  _kernver="$(cat /usr/lib/modules/${_extramodules}/version)"

  # Actually install
  make -C "/usr/lib/modules/${_kernver}/build" \
    INSTALL_MOD_PATH="${pkgdir}/usr" \
    M="${srcdir}/${_pkgname}-${__pkgname}-${pkgver}" modules_install

  cd "${pkgdir}/usr/lib/modules"
  mv "${_kernver}/extra" "${_extramodules}"
  rmdir "${_kernver}"

  # compress kernel modules
  find "${pkgdir}" -name "*.ko" -exec gzip -9 {} +

  # load module on startup
  install -dm 755 "${pkgdir}/usr/lib/modules-load.d"
  echo ${_pkgname} > "${pkgdir}/usr/lib/modules-load.d/${_pkgname}${_kernelname}.conf"

  # Set the correct extramodules directory for install
  cp -f "${startdir}/${install}" "${startdir}/${install}.pkg"
  true && install=${install}.pkg
  sed -i "s/^_EXTRAMODULES=.*/_EXTRAMODULES="${_extramodules}"/" "${startdir}/${install}"
}