# U-Boot: UDOO
# Maintainer: André Silva <emulatorman@hyperbola.info>

buildarch=4

pkgbase=uboot-udoo
pkgname=('uboot-udoo_dl' 'uboot-udoo_quad')
pkgver=2015.01
pkgrel=1
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
makedepends=('bc')
depends=('linux-libre')
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        '0002-kernel-add-support-for-gcc-5.patch')
md5sums=('7f08dc9e98a71652bd6968888ed6ec95'
         'f5e3488e5f2e0646f7e2965c8d5c52d5'
         '721a46867e189d8dedc6b6f86a536a34')

prepare() {
  cd u-boot-${pkgver}

  patch -Np1 -i ../0001-parabola-arm-modifications.patch
  patch -Np1 -i ../0002-kernel-add-support-for-gcc-5.patch
}

build() {
  cd u-boot-${pkgver}
  
  unset CFLAGS CXXFLAGS LDFLAGS
  
  mkdir bins
  for i in dl quad; do
    make distclean
    make udoo_${i}_config
    make
    mv u-boot.imx bins/u-boot-${i}.imx
  done
}

package_uboot-udoo_dl() {
  pkgdesc="U-Boot for UDOO Dual"
  replaces=('uboot-udoo-dual-linux-libre' 'uboot-udoo-dual-linux-libre-grsec'
            'uboot-udoo-dual')
  conflicts=('uboot-udoo' 'uboot4extlinux-udoo' 'uboot4grub-udoo')
  provides=('uboot-udoo')
  install=${pkgbase}.install

  mkdir -p "${pkgdir}"/boot
  cp u-boot-${pkgver}/bins/u-boot-dl.imx "${pkgdir}"/boot/u-boot.imx
}

package_uboot-udoo_quad() {
  pkgdesc="U-Boot for UDOO Quad"
  replaces=('uboot-udoo-quad-linux-libre' 'uboot-udoo-quad-linux-libre-grsec'
            'uboot-udoo-quad')
  conflicts=('uboot-udoo' 'uboot4extlinux-udoo' 'uboot4grub-udoo')
  provides=('uboot-udoo')
  install=${pkgbase}.install

  mkdir -p "${pkgdir}"/boot
  cp u-boot-${pkgver}/bins/u-boot-quad.imx "${pkgdir}"/boot/u-boot.imx
}