# U-Boot: BeagleBone and BeagleBone Black
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Jookia <166291@gmail.com>
# Contributor: Márcio Silva <coadde@hyperbola.info>

buildarch=4

pkgname=uboot4extlinux-am335x_bone
pkgver=2015.04
pkgrel=3
pkgdesc="U-Boot with Extlinux support for BeagleBone and BeagleBone Black"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
conflicts=('uboot-am335x_bone' 'uboot4grub-am335x_bone')
makedepends=('bc')
license=('GPL')
backup=(boot/extlinux/extlinux.conf)
install=${pkgname}.install
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        'extlinux.conf'
        'uEnv.txt')
md5sums=('570bdc2c47270c2a98ca60ff6c5c74cd'
         '37784c8f8f52a615d65e775018d237fb'
         '2a20e20b446f8f28cac3c7a092b0d09f'
         'ccb79775b81654e16fca18825c7f2506')

prepare() {
  cd u-boot-${pkgver}
  patch -Np1 -i ../0001-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}

  unset CFLAGS CXXFLAGS LDFLAGS

  make distclean
  make am335x_evm_config
  make
}

package() {
  cd u-boot-${pkgver}
  mkdir -p "${pkgdir}"/boot/extlinux
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}"/boot
  cp "${srcdir}"/extlinux.conf "${pkgdir}"/boot/extlinux
}