# $Id: PKGBUILD 189356 2016-09-15 20:21:37Z svenstaro $
# Contributor (Arch): Aaron Griffin <aaron@archlinux.org>
# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=vim-colorsamplerpack-libre
pkgname=vim-colorsamplerpack
pkgver=2012.10.28
pkgrel=4.parabola1
_scriptid=18915
pkgdesc="Different colorschemes for vim, without nonfree colorschemes"
arch=('any')
url="http://www.vim.org/scripts/script.php?script_id=625"
license=('GPL2' 'GPL3' 'custom')
replaces=($_pkgname)
conflicts=($_pkgname)
depends=('vim')
makedepends=('unzip')
groups=('vim-plugins')
mksource=(ColorSamplerPack.zip::"http://www.vim.org/scripts/download_script.php?src_id=$_scriptid")
source=("https://repo.parabola.nu/other/${_pkgname}/ColorSamplerPack-libre.tar.xz"
        'LICENSE')
mkmd5sums=('b0f1bd54b396e3d6032c01ef1fb421b6')
md5sums=('73d62829a9ad2cde3f1d03a3fbe154ee'
         'f4639ddafc68f49395c25fb4caf0d6f7')

mksource() {
   # Remove nonfree colorschemes
   cd ${srcdir}
   mv colors colors-tmp
   install -d colors
   install -m644 colors-tmp/{calmar256-light,cleanphp,dante,ekvoli,lettuce,marklar,martin_krischik,motus,railscasts,relaxedgreen,synic,tabula,vibrantink,vividchalk,xoria256,zenburn}.vim colors
   rm -rv colors-tmp
}

package() {
    cd ${srcdir}
    installpath="${pkgdir}/usr/share/vim/vim80"
    install -d $installpath/colors/
    install -m644 colors/* $installpath/colors
    install -D -m644 plugin/color_sample_pack.vim $installpath/plugin/themes.vim
    install -D -m644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}