# Maintainer (Arch): Christian Hesse <mail@eworm.de>
# Contributor: Andreas Grapentin <andreas@grapentin.org>

_basekernel=5.4.78

pkgname=wireguard-lts
_pkgver_x86_64=1.0.20201112
_pkgver_i686=0.0.20200105
_pkgver_armv7h=0.0.20200128
eval "pkgver=\$_pkgver_${CARCH}"
pkgrel=1
pkgrel+=.parabola1.basekernel${_basekernel%-*}
pkgdesc='Wireguard module for LTS Kernel'
pkgdesc+=' (built for the linux-libre-lts kernel package)'
url='https://www.wireguard.com/'
arch=('x86_64')
arch+=('i686' 'armv7h')
license=('GPL')
makedepends=(linux-libre-lts-headers=${_basekernel%-*} libelf "wireguard-dkms>=$pkgver")
conflicts=('wireguard-dkms')
provides=('WIREGUARD-MODULE')

build() {
    _kernver="$(</usr/src/linux-libre-lts/version)"

    fakeroot dkms build --dkmstree "$srcdir" -m wireguard/$pkgver -k $_kernver
}

package() {
  depends=(linux-libre-lts=${_basekernel%-*})

  _kernver="$(</usr/src/linux-libre-lts/version)"

  install -Dt "$pkgdir/usr/lib/modules/$_kernver/extramodules" -m0644 \
    wireguard/${pkgver}/$_kernver/$CARCH/module/*

  # compress each module individually
  find "$pkgdir" -name '*.ko' -exec xz -T1 {} +
}