# $Id: PKGBUILD 71678 2010-03-08 11:58:02Z jgc $
# Maintainer: Alexander Baldeck <alexander@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Maintainer (Parabola): fauno <fauno@kiwwwi.com.ar>
pkgname=xorg-fonts-100dpi-libre
pkgver=1.0.3
pkgrel=2
pkgdesc="X.org 100dpi fonts"
arch=(any)
url="http://xorg.freedesktop.org/"
license=('custom')
depends=('xorg-fonts-encodings' 'xorg-fonts-alias' 'xorg-font-utils' 'fontconfig')
groups=('xorg')
provides=("xorg-fonts-100dpi=$pkgver")
conflicts=('xorg-fonts-100dpi')
replaces=('xorg-fonts-100dpi')
install=xfonts.install
source=(${url}/releases/individual/font/font-adobe-100dpi-$pkgver.tar.bz2
        ${url}/releases/individual/font/font-bitstream-100dpi-$pkgver.tar.bz2)

build() {
  cd "${srcdir}"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"

  for dir in font-*-100dpi*; do
    if [ -d "${dir}" ]; then
      pushd ${dir}
      ./configure --prefix=/usr \
          --with-fontdir=/usr/share/fonts/100dpi
      make || return 1
      make DESTDIR="${pkgdir}" install || return 1
  
      install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.${dir%-100dpi-*}" || return 1
      popd
    fi
  done
  rm -f "${pkgdir}"/usr/share/fonts/100dpi/fonts.*
}
md5sums=('1347c3031b74c9e91dc4dfa53b12f143'
         '6b223a54b15ecbd5a1bc52312ad790d8')