# Maintainer (Arch): AndyRTR <andyrtr@archlinux.org>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: fauno <fauno@kiwwwi.com.ar>

pkgname=xorg-fonts-100dpi
pkgver=1.0.3
pkgrel=4
pkgrel+=.par1
pkgdesc="X.org 100dpi fonts"
arch=('any')
url="https://xorg.freedesktop.org/"
license=('custom')
depends=('xorg-fonts-encodings' 'xorg-fonts-alias' 'xorg-font-utils' 'fontconfig')
groups=('xorg')
conflicts=('xorg-fonts-100dpi-libre')
replaces=('xorg-fonts-100dpi-libre')
source=(${url}/releases/individual/font/font-adobe-100dpi-$pkgver.tar.bz2
        ${url}/releases/individual/font/font-bitstream-100dpi-$pkgver.tar.bz2)
sha256sums=('b2c08433eab5cb202470aa9f779efefce8d9cab2534f34f3aa4a31d05671c054'
            'ebe0d7444e3d7c8da7642055ac2206f0190ee060700d99cd876f8fc9964cb6ce')

build() {
  cd "${srcdir}"
  for dir in font-*-100dpi*; do
    if [ -d "${dir}" ]; then
      pushd ${dir}
      ./configure --prefix=/usr \
          --with-fontdir=/usr/share/fonts/100dpi
      make
      popd
    fi
  done
}

package() {
  cd "${srcdir}"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  for dir in font-*-100dpi*; do
    if [ -d "${dir}" ]; then
      pushd ${dir}
      make DESTDIR="${pkgdir}" install
      install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.${dir%-100dpi-*}"
      popd
    fi
  done
  rm -f "${pkgdir}"/usr/share/fonts/100dpi/fonts.*
}