# $Id: PKGBUILD 71678 2010-03-08 11:58:02Z jgc $
# Maintainer (Arch): Alexander Baldeck <alexander@archlinux.org>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: fauno <fauno@kiwwwi.com.ar>
pkgname=xorg-fonts-100dpi
pkgver=1.0.3
pkgrel=2.parabola2
pkgdesc="X.org 100dpi fonts"
arch=(any)
url="http://xorg.freedesktop.org/"
license=('custom')
depends=('xorg-fonts-encodings' 'xorg-fonts-alias' 'xorg-font-utils' 'fontconfig')
groups=('xorg')
conflicts=('xorg-fonts-100dpi-libre')
replaces=('xorg-fonts-100dpi-libre')
install=xfonts.install
source=(${url}/releases/individual/font/font-adobe-100dpi-$pkgver.tar.bz2
        ${url}/releases/individual/font/font-bitstream-100dpi-$pkgver.tar.bz2)
md5sums=('1347c3031b74c9e91dc4dfa53b12f143'
         '6b223a54b15ecbd5a1bc52312ad790d8')

build() {
  cd "${srcdir}"
  for dir in font-*-100dpi*; do
    if [ -d "${dir}" ]; then
      pushd ${dir}
      ./configure --prefix=/usr \
          --with-fontdir=/usr/share/fonts/100dpi
      make
      popd
    fi
  done
}

package() {
  cd "${srcdir}"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  for dir in font-*-100dpi*; do
    if [ -d "${dir}" ]; then
      pushd ${dir}
      make DESTDIR="${pkgdir}" install
      install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.${dir%-100dpi-*}"
      popd
    fi
  done
  rm -f "${pkgdir}"/usr/share/fonts/100dpi/fonts.*
}