# Maintainer (Arch): Andreas Radke <andyrtr@archlinux.org>
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=xorg-fonts-75dpi
pkgver=1.0.3
pkgrel=4
pkgrel+=.par1
pkgdesc="X.org 75dpi fonts"
arch=(any)
url="https://xorg.freedesktop.org/"
license=('custom')
depends=(xorg-fonts-encodings xorg-fonts-alias xorg-font-utils fontconfig)
groups=('xorg')
conflicts=('xorg-fonts-75dpi-libre')
replaces=('xorg-fonts-75dpi-libre')
source=(${url}/releases/individual/font/font-adobe-75dpi-$pkgver.tar.bz2
        ${url}/releases/individual/font/font-bitstream-75dpi-$pkgver.tar.bz2)
sha256sums=('c6024a1e4a1e65f413f994dd08b734efd393ce0a502eb465deb77b9a36db4d09'
            'ba3f5e4610c07bd5859881660753ec6d75d179f26fc967aa776dbb3d5d5cf48e')

build() {
  cd "${srcdir}"
  for dir in *; do
    if [ -d "${dir}" ]; then
      pushd "${dir}"
      ./configure --prefix=/usr \
          --with-fontdir=/usr/share/fonts/75dpi
      make
      popd
    fi
  done
}

package() {
  cd "${srcdir}"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  for dir in *; do
    if [ -d "${dir}" ]; then
      pushd "${dir}"
      make DESTDIR="${pkgdir}" install
      install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.${dir%-75dpi-*}"
      popd
    fi
  done
  rm -f "${pkgdir}"/usr/share/fonts/75dpi/fonts.*
}