# $Id: PKGBUILD 71681 2010-03-08 12:06:26Z jgc $
# Maintainer (Arch): Alexander Baldeck <alexander@archlinux.org>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
pkgname=xorg-fonts-75dpi
pkgver=1.0.3
pkgrel=2.parabola2
pkgdesc="X.org 75dpi fonts"
arch=(any)
url="http://xorg.freedesktop.org/"
license=('custom')
depends=(xorg-fonts-encodings xorg-fonts-alias xorg-font-utils fontconfig)
groups=('xorg')
conflicts=('xorg-fonts-75dpi-libre')
replaces=('xorg-fonts-75dpi-libre')
install=xfonts.install
source=(${url}/releases/individual/font/font-adobe-75dpi-$pkgver.tar.bz2
        ${url}/releases/individual/font/font-bitstream-75dpi-$pkgver.tar.bz2)
md5sums=('6c9f26c92393c0756f3e8d614713495b'
         'd7c0588c26fac055c0dd683fdd65ac34')

build() {
  cd "${srcdir}"
  for dir in *; do
    if [ -d "${dir}" ]; then
      pushd "${dir}"
      ./configure --prefix=/usr \
          --with-fontdir=/usr/share/fonts/75dpi
      make
      popd
    fi
  done
}

package() {
  cd "${srcdir}"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  for dir in *; do
    if [ -d "${dir}" ]; then
      pushd "${dir}"
      make DESTDIR="${pkgdir}" install
      install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.${dir%-75dpi-*}"
      popd
    fi
  done
  rm -f "${pkgdir}"/usr/share/fonts/75dpi/fonts.*
}