# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=xorg-fonts-type1
pkgver=7.7
pkgrel=3
pkgrel+=.par1
pkgdesc="X.org Type1 fonts, without nonfree fonts"
arch=(any)
license=('custom')
url="https://xorg.freedesktop.org/"
depends=(xorg-fonts-encodings xorg-fonts-alias xorg-font-utils fontconfig)
conflicts=('xorg-fonts-type1-libre')
replaces=('xorg-fonts-type1-libre')
source=(${url}/releases/individual/font/font-bitstream-type1-1.0.3.tar.bz2
        ${url}/releases/individual/font/font-xfree86-type1-1.0.4.tar.bz2)
sha256sums=('c6ea0569adad2c577f140328dc3302e729cb1b1ea90cd0025caf380625f8a688'
            'caebf42aec7be7f3bd40e0f232d6f34881b853dc84acfcdf7458358701fbe34a')

build() {
  cd "${srcdir}"
  for dir in *; do
    if [ -d "${dir}" ]; then
      pushd "${dir}"
      ./configure --prefix=/usr \
        --with-fontdir=/usr/share/fonts/Type1
      make
      popd
    fi
  done
}

package() {
  cd "${srcdir}"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  for dir in *; do
    if [ -d "${dir}" ]; then
      pushd "${dir}"
      make DESTDIR="${pkgdir}" install
      install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.${dir%-*}"
      popd
    fi
  done
  rm -f "${pkgdir}"/usr/share/fonts/Type1/fonts.*
}