# $Id$
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Maintainer (Parabola): André Silva <andre.paulista@adinet.com.uy>

_pkgname=xscreensaver
pkgname=xscreensaver-libre
pkgver=5.15
pkgrel=3
pkgdesc="Screen saver and locker for the X Window System (without non-free asm files)"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.jwz.org/xscreensaver/"
license=('BSD')
depends=('libxxf86vm' 'libglade' 'mesa' 'pam' 'xorg-appres' 'libxmu' \
         'perl-libwww' 'perl-http-message')
makedepends=('bc' 'libxpm' 'gdm')
optdepends=('gdm: for login manager support')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
backup=('etc/pam.d/xscreensaver')
source=(http://www.jwz.org/xscreensaver/${_pkgname}-${pkgver}.tar.gz \
        add-electricsheep.diff xscreensaver.pam LICENSE libre.patch)
sha1sums=('b5ce7caa19f4d57c3bac83377a36dddbe7095052'
          '677496218b81a42d90bee400026e94dd87fb8ffb'
          '106635aa1aae51d6f0668b1853f6c49a4fe9d3d8'
          '4209ea586b204fd1d81c382a0522c654f9fd9134'
          '327b839eb5d069827c1f25ef19fc8d4e83de7ab2')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  patch -p0 -i "${srcdir}/add-electricsheep.diff"
  patch -Np1 -i "${srcdir}/libre.patch" # deleting dmsc.asm file due that doesn't has source code supplied
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib --with-x-app-defaults=/usr/share/X11/app-defaults \
    --with-pam --with-login-manager --with-gtk --with-gl \
    --without-gle --with-pixbuf --with-jpeg
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make install_prefix="${pkgdir}" install
  install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
  install -D -m644 ../xscreensaver.pam "${pkgdir}/etc/pam.d/xscreensaver"
  chmod 755 "${pkgdir}/usr/bin/xscreensaver"
  echo "NotShowIn=KDE;GNOME;" >> "${pkgdir}/usr/share/applications/xscreensaver-properties.desktop"
}