# Maintainer (Arch): Martin Poehlmann <mpdeimos@outlook.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@parabola.nu>

pkgname=california
pkgver=0.4.0
pkgrel=2.6.nonprism1
pkgdesc='A new calendar application for GNOME 3. It is currently under heavy development, without Google Calendar support'
arch=('i686' 'x86_64' 'armv7h')
url="https://wiki.gnome.org/Apps/California"
license=('LGPL2.1')
depends=('evolution-data-server' 'libgee' 'xdg-utils')
makedepends=('vala' 'intltool' 'gnome-common' 'yelp-tools' 'gobject-introspection' 'patch')
install="${pkgname}.install"
source=('https://download.gnome.org/sources/california/0.4/california-0.4.0.tar.xz'
        '0002-Build-with-evolution-data-server-3.13.90.patch'
        'nonprism.patch')
sha256sums=('b25f356363a9f8f8f93c7ab78af02de39f9c3b71964663129ac9904de9147eb6'
            'f512f50470954ec4018c99c49c37fa7e23074653a2e090ff13e32631ec10293d'
            '2c75a8170f97658776d66f2bc8c39afdc27f5ef1e69f59df32f3b7c8dbe30cc5')

prepare() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	# remove Google Calendar support
	patch -Np1 -i "${srcdir}/nonprism.patch"

	rm -rv src/activator/google

	cd po
	for file in *.po; do
	  intltool-update ${file%.*}
	  msgattrib --no-obsolete -o $file $file
	done
}

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	patch -p1 < ../0002-Build-with-evolution-data-server-3.13.90.patch
	./configure \
		--prefix=/usr
	sed -i 's#californiadocdir = ${prefix}#californiadocdir = ${datadir}#g' Makefile
        sed -i 's/static const/const/' src/host/host-main-window.vala
        sed -i 's/static const/const/' src/application/california-application.vala
	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make install DESTDIR="$pkgdir"
	install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/LICENSE
}