# $Id: PKGBUILD 139746 2015-09-10 04:55:04Z foutrelis $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Aaron Griffin <aaron@archlinux.org>
# Contributor (Arch): shild <sxp@bk.ru>

pkgname=centerim
pkgver=4.22.10
pkgrel=4.nonprism1
pkgdesc="Fork of CenterICQ - A text mode menu- and window-driven IM interface, without support for unsafe and dangerous for privacy protocols"
arch=('i686' 'x86_64')
url="http://www.centerim.org"
license=('GPL')
depends=('python2' 'libjpeg' 'gpgme')
replaces=('centericq' "${pkgname}-nonprism")
conflicts=(${pkgname}-nonprism)
source=("http://www.centerim.org/download/releases/$pkgname-$pkgver.tar.gz"
        'nonprism.patch')
md5sums=('7565c3c8cac98a4e2d8524076a44676f'
         '74887744683b68ea37d4d020c80fb675')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  # add patch to remove more protocols
  patch -Np1 -i "${srcdir}/nonprism.patch"
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  sed -i 's#python#python2#' misc/CenterIMLog2HTML.py
  sed -i '1,1i#include <stdio.h>' libicq2000/libicq2000/sigslot.h
  ./configure --prefix=/usr \
              --with-ssl \
              --with-openssl \
              --enable-locales-fix \
              --disable-icq \
              --disable-yahoo \
              --disable-aim \
              --disable-gg \
              --disable-msn
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}