# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
# Contributor (ConnochaetOS): Henry Jensen <hjensen@connochaetos.org>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: vando <facundo@esdebian.org>
# Contributor (Arch): Jakub Schmidtke <sjakub@gmail.com>
# Contributor: Figue <ffigue at gmail>
# Contributor: taro-k <taro-k@movasense_com>
# Contributor: Michał Masłowski <mtjm@mtjm.eu>
# Contributor: Luke R. <g4jc@openmailbox.org>
# Contributor: Isaac David <isacdaavid@isacdaavid.info>
# Thank you very much to the older contributors:
# Contributor: evr <evanroman at gmail>
# Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com>

_pgo=false

# We're getting this from Debian Sid
_debname=firefox
_brandingver=49.0
_brandingrel=1
_debver=49.0
_debrel=deb1
_debrepo=http://ftp.debian.org/debian/pool/main/
_parabolarepo=https://repo.parabola.nu/other/iceweasel
debfile() { echo $@|sed -r 's@(.).*@\1/&/&@'; }

_pkgname=firefox
pkgname=iceweasel
epoch=1
pkgver=$_debver.$_debrel
pkgrel=4.nonprism1

pkgdesc="A libre version of Debian Iceweasel, the standalone web browser based on Mozilla Firefox."
arch=(i686 x86_64 armv7h)
license=(MPL GPL LGPL)
depends=(alsa-lib dbus-glib ffmpeg gtk2 gtk3 hunspell icu=57.1 libevent libvpx=1.6.0 libxt mime-types mozilla-common nss sqlite startup-notification ttf-font)
makedepends=(autoconf2.13 diffutils gconf imagemagick imake inetutils libidl2 libpulse librsvg-stable libxslt mesa mozilla-searchplugins pkg-config python2 quilt unzip yasm zip)
makedepends_i686=(rust)
makedepends_x86_64=("${makedepends_i686[@]}")
options=(!emptydirs !makeflags debug)
if $_pgo; then
  makedepends+=(xorg-server-xvfb)
  options+=(!ccache)
fi
optdepends=('networkmanager: Location detection via available WiFi networks'
            'libnotify: Notification integration'
            'upower: Battery API')
url="https://wiki.parabola.nu/$pkgname"
replaces=("$pkgname-libre" "$_pkgname")
conflicts=("$pkgname-libre")
source=("$_debrepo/`debfile $_debname`_$_debver.orig.tar.xz"
        "$_debrepo/`debfile $_debname`_$_debver-${_debrel#deb}.debian.tar.xz"
        "$_parabolarepo/${pkgname}_$_brandingver-$_brandingrel.branding.tar.xz"
        "$_parabolarepo/${pkgname}_$_brandingver-$_brandingrel.branding.tar.xz.sig"
        mozconfig
        libre.patch
        remove-default-and-shell-icons-in-packaging-manifest.patch
        gnu_headshadow.png
        drm-free.png
        $pkgname.desktop
        $pkgname-install-dir.patch
        vendor.js
        enable-object-directory-paths.patch
        mozilla-1253216.patch
        mozilla-build-arm.patch)
sha512sums=('08e954ab904f114a2604c74c6a691afeeea48c08be31def836e1654175f9afb748b08e19a4cf0814a83c5f1a1aa6f51b1076e9e701dade661880b0bbf228b524'
            '06be4fe3e09f56d0a36b59513ec70c1990ded0aee0d01bf425e00285eb2b4a61059c67356d90f9ab1805ac7c8e72fa14ab559c1d396b12fcb1e267e53ac7f276'
            'ab20ea7a56528abb04e1f392f6a1d3368e946292a1741578e8768dee7ab2687c01faf90e2cda2a4f936033c21bc93d2e20459bb6d8c2d3cc15e2eb62cd02aaab'
            '568416b981c300bb445d883ae84c79226d8fc126280ca48702653485084c80ef27fde5fc2acc351b7f88fc73a5a05dc740de6d1e731639acfc6d3298ae4e30dd'
            'a2ef9a1a9daa4305296570d9cf44abd53218979d9f09cb1040f22e9d0e0b385906be1cb9e19bbc8b9ce02074bf40c3eb9031ffa1355c32ee8387ba37fd3b4a0c'
            '67f3bf5279522a3500bda32a4b916e1d74dc06627cb5d5a72662bb005db41c37c08a37acd493f622c14a267ad994723571f3b8ee610e6dd67f171c6da094654d'
            '6b76f61db3036d15aacac4af767814665398243a2ad55cc11c4d58e3f2ce1740c5c4706559b919f823405f69aa89d92486ed94e0caca72b52abb703f68f5b43a'
            '76ac01f250975688439a31206f60d3ee05aa74a9cff7922ba9eab3fb3906bba176bab6dcff1791c19ca6acffed5167af841ab077d49ba1889020e5f827d34a60'
            'ac68873be1c76fd166f7a26fd2475540065b9b2d841185a346cbe3bd92645904f35f1c2a4ffc9153b638aaa419182ad2a7dea7efde91267d9eee38a312dce0cb'
            '5860c7be67eb5a33c12d58267e06f6fa282d42c9affd9211d88b8bede3ef77058fc1d0f818745c1417a15e1ea58e9ea07a45aab3810865d5275ed1e12b146588'
            'cddffc04032686644b61509ea696cd36333327015e3a52f99afd23c74f18d82bec34619759f7acb053e10a7288d2d658d87350f5b4fc9e56ff2337c38aa4b5c6'
            '0bec9fcc49e7227f1b69b723ceaf592e00352524c23c2d993d3e04f9d5c8b65bad1f2cea3d0ab0e274a61bb3c4561fc932834cdde6306c4033eb037fc8a9237e'
            'f60f59b5d11b9ce5ad4c01eedae78f27131f17b07720e5ac35441d43e95987d81b9b2680e7258d73b1a8092fe3ae554072d07a41d6b337af82742886196bc375'
            '27614fca622700a1b16e0b2d286891add93a71ba4189a675740e67fb5fb91a1971dbde2dfa11a9c0f875a627c1a3c82645eef081d64c892f958bcbdb3a863cae'
            '5f26d81dc0475b2c68e653dd95d6cf9ac70cd1b944eb12fd2c637fb4c5777d2c00e92ea97b6827819c3f6dce40814eeac1e99d4900eb35bffbe77a76d3c834c5')
validpgpkeys=(
              'C92BAA713B8D53D3CAE63FC9E6974752F9704456' # André Silva
              '684D54A189305A9CC95446D36B888913DDB59515' # Márcio Silva
)

prepare() {
  cd "$srcdir/$_pkgname-$_debver"
  mv "$srcdir/debian" .
  mv "$srcdir/$pkgname-$_brandingver/branding" debian
  mv "$srcdir/$pkgname-$_brandingver/patches/iceweasel-branding" debian/patches
  cat "$srcdir/$pkgname-$_brandingver/patches/series" >> debian/patches/series

  export QUILT_PATCHES=debian/patches
  export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
  export QUILT_DIFF_ARGS='--no-timestamps'

  quilt push -av

  # Put gnu_headshadow.png and drm-free.png in the source code
  install -m644 "$srcdir/"{gnu_headshadow,drm-free}.png \
    browser/base/content/abouthome

  # Useless since we are doing it ourselves
  patch -Np1 -i "$srcdir/remove-default-and-shell-icons-in-packaging-manifest.patch"

  # Enable object directory paths for Iceweasel rebranding
  patch -Np1 -i "$srcdir/enable-object-directory-paths.patch"

  # Install to /usr/lib/$pkgname
  patch -Np1 -i "$srcdir/$pkgname-install-dir.patch"

  # Disable various components at the source level
  sed -i 's|1|0|' toolkit/components/telemetry/TelemetryStartup.manifest || die "failed break telemetry startup"
  sed -i 's|1|0|' browser/experiments/Experiments.manifest || die "failed to break ExperimentsService"
  sed -i '/pocket/d' browser/extensions/moz.build || die "failed to wipe pocket"

  # Patch and remove anything that's left
  patch -Np1 -i "$srcdir/libre.patch"
  sed -i 's|Adobe Flash|SWF Player|g;
         ' browser/base/content/pageinfo/permissions.js \
           browser/base/content/browser-plugins.js
  sed -i '\|["]displayName["][:] ["]Flash["]| s|Flash|SWF Player|
          \|["]displayName["][:] ["]Shockwave["]| s|Shockwave|DCR Player|
          \|["]displayName["][:] ["]QuickTime["]| s|QuickTime|MOV Player|
          \|installLinux| s|true|false|
         ' browser/base/content/browser-plugins.js

  # Load our build config, disable SafeSearch
  cp "$srcdir/mozconfig" .mozconfig

  mkdir "$srcdir/path"
  ln -s /usr/bin/python2 "$srcdir/path/python"

  # Load our searchplugins
  rm -rv browser/locales/en-US/searchplugins
  cp -av /usr/lib/mozilla/searchplugins browser/locales/en-US

  # ARM-specific changes:
  if [[ "$CARCH" == arm* ]]; then
      sed -i '/ac_add_options --enable-rust/d' .mozconfig
      echo "ac_add_options --disable-ion" >> .mozconfig
      echo "ac_add_options --disable-elf-hack" >> .mozconfig
      echo "ac_add_options --disable-webrtc" >> .mozconfig

      # Disable gold linker, reduce memory consumption at link time
      sed -i '/ac_add_options --enable-gold/d' .mozconfig
      LDFLAGS+=" -Wl,--no-keep-memory -Wl,--reduce-memory-overheads"
      echo "ac_add_options --disable-tests" >> .mozconfig
      echo "ac_add_options --disable-debug" >> .mozconfig

      patch -p1 -i ../mozilla-1253216.patch
      patch -p1 -i ../mozilla-build-arm.patch
  fi
}

build() {
  cd "$srcdir/$_pkgname-$_debver"

  # _FORTIFY_SOURCE causes configure failures
  CPPFLAGS+=" -O2"

  # Hardening
  LDFLAGS+=" -Wl,-z,now"

  # GCC 6
  CXXFLAGS+=" -fno-delete-null-pointer-checks -fno-schedule-insns2"

  export PATH="$srcdir/path:$PATH"

  if $_pgo; then
    # Do PGO
    xvfb-run -a -s "-extension GLX -screen 0 1280x1024x24" \
      make -f client.mk build MOZ_PGO=1
  else
    make -f client.mk build
  fi
}

package() {
  cd "$srcdir/$_pkgname-$_debver"
  make -f client.mk DESTDIR="$pkgdir" INSTALL_SDK= install

  install -Dm644 ../vendor.js "$pkgdir/usr/lib/$pkgname/browser/defaults/preferences/vendor.js"

  _brandingdir=debian/branding
  brandingdir=moz-objdir/$_brandingdir
  icondir="$pkgdir/usr/share/icons/hicolor"
  for i in 16 22 24 32 48 64 128 192 256 384; do
    rsvg-convert -w $i -h $i "$_brandingdir/${pkgname}_icon.svg" \
      -o "$brandingdir/default$i.png"
    install -Dm644 "$brandingdir/default$i.png" \
      "$icondir/${i}x${i}/apps/$pkgname.png"
  done

  install -Dm644 "$_brandingdir/${pkgname}_icon.svg" \
    "$icondir/scalable/apps/$pkgname.svg"

  install -d "$pkgdir/usr/share/applications"
  install -m644 "$srcdir/$pkgname.desktop" \
    "$pkgdir/usr/share/applications"

  # Use system-provided dictionaries
  rm -rf "$pkgdir/usr/lib/$pkgname/"{dictionaries,hyphenation}
  ln -s /usr/share/hunspell "$pkgdir/usr/lib/$pkgname/dictionaries"
  ln -s /usr/share/hyphen   "$pkgdir/usr/lib/$pkgname/hyphenation"

  # Replace duplicate binary with symlink
  # https://bugzilla.mozilla.org/show_bug.cgi?id=658850
  ln -sf $pkgname "$pkgdir/usr/lib/$pkgname/$pkgname-bin"
}