# $Id: PKGBUILD 280506 2016-11-10 19:20:03Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=kdenetwork-kopete
pkgver=16.08.3
pkgrel=1.parabola1.nonprism1
pkgdesc='Instant Messenger, without nonfree Skype support and support for unsafe and dangerous for privacy protocols'
url='http://kde.org/applications/internet/kopete/'
arch=('i686' 'x86_64' 'armv7h')
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdenetwork')
replaces=(${pkgname}-libre ${pkgname}-libre-nonprism)
conflicts=(${pkgname}-libre ${pkgname}-libre-nonprism)
depends=('kdebase-runtime' 'libotr' 'qimageblitz' 'kdepimlibs4')
makedepends=('cmake' 'automoc4' 'boost' 'mediastreamer' 'jsoncpp')
optdepends=('mediastreamer: jingle support')
source=("http://download.kde.org/stable/applications/${pkgver}/src/kopete-${pkgver}.tar.xz"
        'kopete-mediastreamer2.14.patch'
        'libre-nonprism.patch')
sha1sums=('5ffbfd68c91ce251bf7f22943bc8cb8284b30eaa'
          'b284ffb226cbcc0da6540ecd978d37287aa6eddb'
          'f0d7b727da1b5160f05952eec4df1bfbefab99cf')

prepare() {
  cd kopete-$pkgver
  # Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
  rm -rv protocols/skype
  # remove unsafe/dangerous services
  rm -rv protocols/oscar
  rm -rv protocols/yahoo
  rm -rv protocols/qq
  rm -rv protocols/groupwise
  rm -rv protocols/gadu
  rm -rv protocols/wlm
  rm -rv protocols/meanwhile
  patch -p1 -i "${srcdir}"/libre-nonprism.patch
  cd ..
  mkdir -p build

# Fix build with mediastreamer 2.14
  cd kopete-$pkgver
  patch -p1 -i ../kopete-mediastreamer2.14.patch
}

build() {
  cd build
  cmake ../kopete-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DWITH_Libmsn=OFF \
    -DWITH_Libgadu=OFF \
    -DWITH_skype=OFF \
    -DWITH_oscar=OFF \
    -DWITH_yahoo=OFF \
    -DWITH_qq=OFF \
    -DWITH_groupwise=OFF \
    -DWITH_gadu=OFF \
    -DWITH_GOOGLETALK=OFF \
    -DWITH_wlm=OFF \
    -DWITH_WLM_MEDIASTREAMER=OFF \
    -DWITH_meanwhile=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}