# $Id: PKGBUILD 290221 2017-03-09 16:12:45Z arojas $
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=kdepim-addons
pkgver=16.12.3
pkgrel=1.parabola2.nonprism1
pkgdesc='Addons for KDE PIM applications, without libkgapi support (built without nonfree qt5-webengine)'
arch=(i686 x86_64)
url='https://community.kde.org/KDE_PIM'
license=(GPL LGPL FDL)
depends=(mailcommon incidenceeditor libktnef)
makedepends=(extra-cmake-modules kdoctools boost python kdesignerplugin)
groups=(kde-applications kdepim)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
        'libre.patch')
sha256sums=('b5bede3a4b4c29905e93159d18c5fcb6f536e8c1097b25db09fa7877e23e15c3'
            'SKIP'
            'd41170f09bcf6485a6d029f09fc3f104cc8f29cf6ce890999ae9b83b08f26fd7')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid@kde.org>

prepare() {
  mkdir -p build
  cd $pkgname-$pkgver
  patch -p1 -i ../libre.patch
  rm -rv plugins/webengineurlinterceptor
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DBUILD_TESTING=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}