# $Id: PKGBUILD 201659 2013-12-17 13:52:43Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=kdepim-runtime
pkgname=kdepim-runtime-nonprism
pkgver=4.12.0
pkgrel=1
pkgdesc='Extends the functionality of kdepim, without libkgapi and libkfbapi support'
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/kde/kdepim-runtime'
license=('GPL' 'LGPL' 'FDL')
depends=('kdebase-runtime' 'libkolab')
makedepends=('cmake' 'automoc4' 'boost')
install="${_pkgname}.install"
replaces=('kdepim-runtime' 'kdepim-runtime-coherence')
conflicts=kdepim-runtime
provides=kdepim-runtime=$pkgver
source=("http://download.kde.org/stable/${pkgver}/src/${_pkgname}-${pkgver}.tar.xz")
sha1sums=('fe988ea74cf83f1dae99f81bc02eefaa834c664c')

prepare() {
  mkdir build
}

build() {
	cd build
	cmake ../${_pkgname}-${pkgver} \
		-DCMAKE_BUILD_TYPE=Release \
		-DKDE4_BUILD_TESTS=OFF \
		-DCMAKE_INSTALL_PREFIX=/usr
	make
}

package() {
	cd build
	make DESTDIR="${pkgdir}" install
}