# $Id$
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer (Arch): Florian Pritz <bluewind@xinu.at>
# Contributor (Arch): Asa Marco <marcoasa90[at]gmail[.]com>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Freemor <freemor@freemor.ca>

# parabola changes and rationale:
#  - removed faac recommendation and youtube upload support
#  - neuter google analytics and exception tracking as it all happens over http

pkgname=openshot
pkgver=2.4.4
pkgrel=1
pkgrel+=.nonprism1
pkgdesc="a free, non-linear video editor for GNU/Linux based on MLT framework, without nonfree faac recommendation and Youtube uploader support"
arch=('any')
url="http://www.openshot.org/"
license=('GPL')
depends=('mlt-python-bindings' 'sdl' 'librsvg' 'mplayer'
	 'pyxdg' 'python-pyqt5' 'python-httplib2' 'python-pillow' 'dvgrab'
	 'ladspa' 'sox' 'vid.stab' 'qt5-svg' 'sdl_image'
	 'libopenshot' 'python-pyzmq' 'qt5-webkit' 'python-setuptools'
         'python-requests')
optdepends=('frei0r-plugins: effects'
	    'libquicktime' 'libavc1394' 'jack')
makedepends=('python-setuptools')


source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenShot/openshot-qt/archive/v$pkgver.tar.gz"
        'nonprism.patch'
	'neuter_tracking.patch')
sha256sums=('8197923b3fff2010ee69c75469818543674a12fcb8fcb08944471e4ead3426be'
            '31b78e88c83bba0ff469afdbbdc36577ca64a55640e4220e9a88ccf0c7f105dc'
            '3990bdf10f46cd5255d01b0b113fe10e3ffed16da0577dfcaad470edd016aef9')

prepare() {
  cd "$srcdir"/openshot-qt-$pkgver
  patch -Np1 -i $srcdir/nonprism.patch
  patch -Np1 -i $srcdir/neuter_tracking.patch
}

package() {
  cd "$srcdir"/openshot-qt-$pkgver
  python setup.py install --root="$pkgdir/" --optimize=1
}