# $Id: PKGBUILD 189002 2016-09-08 07:25:36Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer (Arch): Florian Pritz <bluewind@xinu.at>
# Contributor (Arch): Asa Marco <marcoasa90[at]gmail[.]com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=openshot
pkgver=2.1.0
pkgrel=3.parabola1.nonprism1
pkgdesc="a free, non-linear video editor for GNU/Linux based on MLT framework, without nonfree faac recommendation and Youtube uploader support"
arch=('any')
url="http://www.openshotvideo.com/"
license=('GPL')
depends=('mlt-python-bindings' 'pygoocanvas' 'sdl' 'librsvg' 'mplayer'
	 'pyxdg' 'python-pyqt5' 'python-httplib2' 'python-pillow' 'dvgrab'
	 'ladspa' 'sox' 'vid.stab' 'qt5-svg' 'sdl_image'
	 'libopenshot' 'python-pyzmq' 'qt5-webkit')
optdepends=('frei0r-plugins: effects'
	    'libquicktime' 'libavc1394' 'jack' 'jack-rack')
makedepends=('python-setuptools')
replaces=("${pkgname}-libre" "${pkgname}-parabola" "${pkgname}-libre-nonprism" "${pkgname}-nonprism")
conflicts=("${pkgname}-libre" "${pkgname}-parabola" "${pkgname}-libre-nonprism" "${pkgname}-nonprism")
source=("https://launchpad.net/openshot/${pkgver%.*}/$pkgver/+download/openshot-qt-$pkgver.tar.gz"
        'nonprism.patch')
md5sums=('b4641ecebc02b1ad1047e3bfb3213774'
         'abbd28224a3044f3952e533de74e531a')
prepare() {
  cd "$srcdir"
  patch -Np1 -i $srcdir/nonprism.patch
}

package() {
  cd "$srcdir"
  python setup.py install --root="$pkgdir/" --optimize=1
}