# Maintainer (Arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor (Arch): Geoffrey Teale <tealeg@stop-squark>
# Contributor (Arch): Mark, Huo Mian <markhuomian[at]gmail[dot]com>
# Contributor (Arch): Biginoz <biginoz a free dot fr>
# Contributor (Arch): Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=redshift
pkgver=1.11
pkgrel=3.nonprism1
pkgdesc='Adjusts the color temperature of your screen according to your surroundings, without geoclue2 support'
arch=('i686' 'x86_64')
url='http://jonls.dk/redshift/'
license=('GPL3')
depends=('libdrm' 'libxcb' 'libxxf86vm')
optdepends=('python-gobject: for redshift-gtk'
            'python-xdg: for redshift-gtk'
            'librsvg: for redshift-gtk')
makedepends=('intltool' 'python')
source=("https://github.com/jonls/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz")
md5sums=('a31d768b0348c5202e58612855a9027e')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr --enable-drm --enable-randr --enable-vidmode \
    --with-systemduserunitdir=/usr/lib/systemd/user
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}