# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Joshua Ismael Haase Hernández (xihh) <hahj87@gmail.com>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@hyperbola.info>

pkgname=libretools
pkgver=20181004
pkgrel=1
pkgrel+=.nonsystemd1
pkgdesc="Programs for Parabola development"
arch=('any')
url="https://git.parabola.nu/packages/libretools.git/"
license=('GPL3' 'GPL2')
backup=(etc/libretools.conf
        etc/libretools.d/chroot.conf
        etc/libretools.d/libredbdiff.conf
        etc/libretools.d/librefetch.conf)
install=libretools.install
conflicts=(devtools libretools-mips64el)
replaces=(libretools-mips64el)
depends=(
  "librelib=$pkgver"
  "gitget=$pkgver" # `createworkdir`
  'pacman>=5.1.1-1.parabola5' 'pacman<5.2'
  arch-install-scripts # `mkarchroot` uses `pacstrap`
  binutils # `libremakepkg` uses `makepkg` uses `strip`
  expac # `libredbdiff`
  fakeroot # `libremakepkg` uses `makepkg` uses `fakeroot`
  make # `librefetch`
  openssh # `librerelease`
  rsync # `librerelease` and `makechrootpkg.sh`
  chroot-nspawn # chroot-nspawn
  tokyocabinet # `toru`
  #namcap # Namcap is currently dissabled in libremakepkg :-(
  subversion # `diff-unfree`
  wget # `aur`, optdepend for librelib:`blacklist`
)
optdepends=('qemu-user-static-binfmt: To build ARM packages from x86')
makedepends=(ruby-ronn)
checkdepends=(
  bash-bats git
  'pacman>=5.1.1-1.parabola5' 'pacman<5.2'
  expac
  openssh
  rsync
  tokyocabinet
)
source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz{,.sig}
        Remove-systemd-support.patch)
sha256sums=('2bdefd1803ba3e6cbd1eb955fad3de9ce8a4abfd23a0bd96a60772762df7b53b'
            'SKIP'
            '4257e7c5383df8c322d79f8e601893f71eeccbd1b9ceac76c8ebbc90fb609875')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9') # Luke Shumaker

build() {
  cd "$srcdir/$pkgbase-$pkgver"

  # Use chroot-nspawn instead of systemd-nspawn
  patch -p1 -i ../Remove-systemd-support.patch

  make
}

check() {
  cd "$srcdir/$pkgbase-$pkgver"

  SUDO_USER= make check TESTENVFLAGS='--no-network --no-sudo'
}

package() {
  cd "$srcdir/$pkgbase-$pkgver"
  make install-libretools DESTDIR="$pkgdir"
}