# Maintainer: bill-auger <bill-auger@programmer.net>


pkgname=calamares
pkgver=3.1.9
pkgrel='parabola9.2'
pkgdesc='Distribution-independent installer framework - Parabola edition'
arch=('i686' 'x86_64')
url="https://calamares.io/"
license=('GPL')

_latest_version() { pacman -Si $1 | awk '$1=="Version"{print $3}' ; }
_build_couplings=("boost=$(_latest_version 'boost')")
_runtime_couplings=("boost-libs=$(_latest_version 'boost')"
                    "icu=$(_latest_version 'icu')"
                    "kpmcore=$(_latest_version 'kpmcore')"
                    "qt5-base=$(_latest_version 'qt5-base')")
makedepends=(${_build_couplings[@]} 'extra-cmake-modules' 'git' 'kservice' \
             'kwindowsystem' 'plasma-framework' 'qt5-tools')
depends=(${_runtime_couplings[@]} 'ckbcomp' 'dmidecode' 'gptfdisk' 'hwinfo' 'kconfig'
         'kcoreaddons' 'ki18n' 'kparts' 'libpwquality' 'os-prober' 'polkit-qt5' 'python'
         'squashfs-tools' 'solid' 'qt5ct' 'qt5-styleplugins' 'qt5-svg' 'yaml-cpp')

_git_tag="v${pkgver}-${pkgrel%%.*}"
_build_dir=${pkgname}-${_git_tag}/build
source=(https://git.parabola.nu/${pkgname}.git/snapshot/${pkgname}-${_git_tag}.tar.gz)
sha256sums=('cc9e9f27cdf45ac8a5ac29ba6d3843e679a992f015998346f6d544c18088d616')


build()
{
  mkdir -p ${srcdir}/${_build_dir}
  cd ${srcdir}/${_build_dir}

  cmake -DCMAKE_BUILD_TYPE=Debug                                                 \
        -DCMAKE_INSTALL_PREFIX=/usr                                              \
        -DCMAKE_INSTALL_LIBDIR=lib                                               \
        -DSKIP_MODULES="dracut dracutlukscfg dummycpp dummyprocess dummypython   \
                        dummypythonqt initramfs initramfscfg interactiveterminal \
                        license plymouthcfg removeuser tracking webview"           ..
}

package()
{
  cd ${srcdir}/${_build_dir}

  make DESTDIR=${pkgdir} install
}